//bittnerRig_3
//copyright 2005 - 2006 by Thomas Bittner


global proc br3_updateField(string $ctrol, string $objecttype)
{
	string $sel[] = `ls -sl -showType -dag`;

	if (($sel[1] == $objecttype) || ($sel[3] == $objecttype))
		textFieldButtonGrp -e -text $sel[0] $ctrol;
	else
		warning ("please select a " + $objecttype);
}

proc rebuildJointsRepeatProc(string $joint)
{
	string $oldjoint;
	$prefix = "_new";
	
	float $jointpos[2] = `xform -q -ws -t $joint`;
	string $eltern[] = `listRelatives -p $joint`;

	if (size($eltern[0]) && `objExists ($eltern[0] + $prefix)`) 
	{
		select ($eltern[0] + $prefix);	
		$oldjoint = $eltern[0] + $prefix;
	}
	else
		select -cl;

	string $newjoint = `joint -n ($joint + $prefix) -p $jointpos[0] $jointpos[1] $jointpos[2]`;

	if ($eltern[0] != "" && `objExists ($eltern[0] + $prefix)` ) 
		joint -e -zso -oj xyz -sao yup $oldjoint;
	
	string $children[] = `listRelatives -c $joint`;
	for ($i = 0;$i<size($children);$i++)
		rebuildJointsRepeatProc($children[$i]);
}



proc rebuildJoints(string $joint)
{
	rebuildJointsRepeatProc($joint);

	$prefix = "_new";
	delete $joint;
	string $newjoints[] = `ls -dag -sn ($joint + $prefix)`;
	for ($i = 0;$i<size($newjoints);$i++)
	{
		string $oldname = startString($newjoints[$i], (size($newjoints[$i]) - size($prefix)));
		rename $newjoints[$i] $oldname;
	}
}

proc hideObjs(string $objs[])
{
	for ($obj in $objs)
		setAttr ($obj + ".visibility") 0;
}

proc palign(string $big,string $small)
{
	select $big $small; string $constrs[] = `pointConstraint`; delete $constrs;
}

proc oalign(string $big,string $small)
{
	select $big $small; string $constrs[] = `orientConstraint`; delete $constrs;
}

proc addparameter(string $object, string $name, string $typ)
{
	addAttr -ln $name -at $typ -min 0 -max 10 -dv 0 $object;
	setAttr -e -keyable true ($object + "." + $name);	
}

proc float getDistance(string $obj1, string $obj2)
{
	float $pos1[] = `xform -q -ws -t $obj1`;
	float $pos2[] = `xform -q -ws -t $obj2`;
	vector $thevector = <<$pos1[0] - $pos2[0], $pos1[1] - $pos2[1], $pos1[2] - $pos2[2]>>;
	return mag($thevector);
}

proc makectroll(string $name, string $type, float $width, float $length, float $height)
{
	global float $br3_size;

	if (`checkBox -q -v br3_cb_buildingprocess`)
		refresh;

	switch ($type)
	{
		case "cube":
			string $thecurve = `curve -d 1 -p -0.5 0.5 -0.5 -p 0.5 0.5 -0.5 -p 0.5 0.5 0.5 
			-p -0.5 0.5 0.5 -p -0.5 0.5 -0.5 -p -0.5 -0.5 -0.5 -p 0.5 -0.5 -0.5 -p 0.5 0.5 -0.5 
			-p 0.5 -0.5 -0.5 -p 0.5 -0.5 0.5 -p 0.5 0.5 0.5 -p 0.5 -0.5 0.5 -p -0.5 -0.5 0.5 
			-p -0.5 0.5 0.5 -p -0.5 -0.5 0.5 -p -0.5 -0.5 -0.5 -p -0.5 0.5 -0.5 -p -0.5 -0.5 -0.5 
			-k 0 -k 1 -k 2 -k 3 -k 4 -k 5 -k 6 -k 7 -k 8 -k 9 -k 10 -k 11 -k 12 -k 13 -k 14 -k 15 
			-k 16 -k 17` ;
		break;
	
		case "sphere":
			string $thecurve = `curve -d 1 -p 0 1 0 -p -0.433013 0.5 0.75 -p -0.433013 -0.5 0.75 -p 0 -1 0 
			-p 0.866025 -0.5 0 -p 0.866025 0.5 0 -p 0 1 0 -p -0.433013 0.5 -0.75 -p -0.433013 -0.5 -0.75 
			-p 0 -1 0 -p 0.866025 -0.5 0 -p -0.433013 -0.5 0.75 -p -0.433013 -0.5 -0.75 -p 0.866025 -0.5 0 
			-p 0.866025 0.5 0 -p -0.433013 0.5 0.75 -p -0.433013 0.5 -0.75 -p 0.866025 0.5 0 -k 0 -k 1 -k 2 -k 3 
			-k 4 -k 5 -k 6 -k 7 -k 8 -k 9 -k 10 -k 11 -k 12 -k 13 -k 14 -k 15 -k 16 -k 17 `;
		break;
		
		case "circle":
			string $col[] = `circle -c 0 0 0 -nr 0 1 0 -sw 360 -r 1 -d 3 -ut 0 -tol 0.01 -s 8 -ch 1`;
			string $thecurve = $col[0];
			setAttr ($thecurve + ".rotateZ") 90;
		break;
		
		case "square":
			string $thecurve = `curve -d 1 -p -0.5 0.5 0 -p 0.5 0.5 0 -p 0.5 -0.5 0 
			-p -0.5 -0.5 0 -p -0.5 0.5 0 -k 0 -k 1 -k 2 -k 3 -k 4`;
			setAttr ($thecurve + ".rx") 90;
		break;
		
		case "cylinder":
			string $thecurve = `curve -d 1 -p 0.5 0.154508 0.475528 -p 0.5 0.5 0 -p -0.5 0.5 0 -p 0.5 0.5 0 
			-p 0.5 0.154509 -0.475528 -p -0.5 0.154509 -0.475528 -p 0.5 0.154509 -0.475528 -p 0.5 -0.404509 -0.293893 
			-p -0.5 -0.404509 -0.293893 -p 0.5 -0.404509 -0.293893 -p 0.5 -0.404509 0.293893 
			-p -0.5 -0.404509 0.293893 -p 0.5 -0.404509 0.293893 -p 0.5 0.154508 0.475528 -p -0.5 0.154508 0.475528 
			-p -0.5 0.5 0 -p -0.5 0.154509 -0.475528 -p -0.5 -0.404509 -0.293893 -p -0.5 -0.404509 0.293893 -p -0.5 0.154508 0.475528 
			-k 0 -k 1 -k 2 -k 3 -k 4 -k 5 -k 6 -k 7 -k 8 -k 9 -k 10 -k 11 -k 12 -k 13 -k 14 -k 15 -k 16 -k 17 -k 18 -k 19` ;
		break;
		
		case "kreuz":
			string $thecurve = `curve -d 1 -p -0.333 0.999 0 -p 0.333 0.999 0 -p 0.333 0.333 0 -p 0.999 0.333 0 -p 0.999 -0.333 0 
			-p 0.333 -0.333 0 -p 0.333 -0.999 0 -p -0.333 -0.999 0 -p -0.333 -0.333 0 -p -0.999 -0.333 0 
			-p -0.999 0.333 0 -p -0.333 0.333 0 -p -0.333 0.999 0 -k 0 -k 1 -k 2 -k 3 -k 4 -k 5 -k 6 -k 7 -k 8 
			-k 9 -k 10 -k 11 -k 12` ;
		break;
		
	}
	
	DeleteHistory;
	setAttr ($thecurve + ".scaleX") ($width * $br3_size);
	setAttr ($thecurve + ".scaleY") ($height * $br3_size);
	setAttr ($thecurve + ".scaleZ") ($length * $br3_size);
	makeIdentity -apply true -t 0 -r 1 -s 1 -n 0;
	rename $thecurve $name;
}


proc mirrorLocs(string $locators[])
{
	for ($i = 0;$i<size($locators);$i++)
	{
		string $newloc = "R_" + `endString $locators[$i] (size($locators[$i]) - 2)`;
		string $locs[] = `duplicate $locators[$i]`;
		$newloc = `rename $locs[0] $newloc`;
		string $group = `group $newloc`;
		xform -os -piv 0 0 0;
		setAttr ($group + ".sx") -1;
		parent -w $newloc;
		delete $group;
	}
	select -cl;	
}




global proc br3_createBipedGuide()
{
	select -cl;
	joint -n "L_shoulder" -p 1.305931529 35.56468632 -1.992311028; select L_shoulder;
	joint -n "L_upperarm" -p 3.829771073 34.89041891 -1.992311028;
	joint -e -zso -oj xyz -sao yup L_shoulder; select L_upperarm;
	joint -n "L_elbow" -p 9.779966418 34.89041891 -2.963322589;
	joint -e -zso -oj xyz -sao yup L_upperarm; select L_elbow;
	joint -n "L_wrist" -p 15.62354818 34.89041914 -1.871186088;
	joint -e -zso -oj xyz -sao yup L_elbow; select L_wrist;
	joint -n "L_wrist2" -p 16.521124 34.89041914 -1.849227996;
	joint -e -zso -oj xyz -sao yup L_wrist; select L_wrist2;
	joint -n "fingers_L_pinkey0" -p 17.03646558 34.89041914 -2.50453348;
	joint -e -zso -oj xyz -sao yup L_wrist2; select fingers_L_pinkey0;
	joint -n "fingers_L_pinkey1" -p 17.42926084 34.89041914 -2.561011698;
	joint -e -zso -oj xyz -sao yup fingers_L_pinkey0; select fingers_L_pinkey1;
	joint -n "fingers_L_pinkey2" -p 17.80280808 34.89041914 -2.614722335;
	joint -e -zso -oj xyz -sao yup fingers_L_pinkey1; select fingers_L_pinkey2;
	joint -n "fingers_L_pinkey3" -p 18.23725582 34.89041914 -2.677189573;
	joint -e -zso -oj xyz -sao yup fingers_L_pinkey2; select L_wrist2;
	joint -n "fingers_L_ringfinger0" -p 17.13548842 34.89041914 -2.201348704;
	joint -e -zso -oj xyz -sao yup L_wrist2; select fingers_L_ringfinger0;
	joint -n "fingers_L_ringfinger1" -p 17.71965065 34.89041914 -2.201348704;
	joint -e -zso -oj xyz -sao yup fingers_L_ringfinger0; select fingers_L_ringfinger1;
	joint -n "fingers_L_ringfinger2" -p 18.2651076 34.89041914 -2.201348704;
	joint -e -zso -oj xyz -sao yup fingers_L_ringfinger1; select fingers_L_ringfinger2;
	joint -n "fingers_L_ringfinger3" -p 18.84926983 34.89041914 -2.201348704;
	joint -e -zso -oj xyz -sao yup fingers_L_ringfinger2; select L_wrist2;
	joint -n "fingers_L_middlefinger0" -p 17.14833758 34.89041914 -1.786573877;
	joint -e -zso -oj xyz -sao yup L_wrist2; select fingers_L_middlefinger0;
	joint -n "fingers_L_middlefinger1" -p 17.9085668 34.89041914 -1.754529871;
	joint -e -zso -oj xyz -sao yup fingers_L_middlefinger0; select fingers_L_middlefinger1;
	joint -n "fingers_L_middlefinger2" -p 18.58059687 34.89041914 -1.726203499;
	joint -e -zso -oj xyz -sao yup fingers_L_middlefinger1; select fingers_L_middlefinger2;
	joint -n "fingers_L_middlefinger3" -p 19.23595477 34.89041914 -1.698579867;
	joint -e -zso -oj xyz -sao yup fingers_L_middlefinger2; select L_wrist2;
	joint -n "fingers_L_index0" -p 17.0364656 34.89041914 -1.425986529;
	joint -e -zso -oj xyz -sao yup L_wrist2; select fingers_L_index0;
	joint -n "fingers_L_index1" -p 17.60714314 34.89041914 -1.301196069;
	joint -e -zso -oj xyz -sao yup fingers_L_index0; select fingers_L_index1;
	joint -n "fingers_L_index2" -p 18.04085806 34.89041914 -1.206355321;
	joint -e -zso -oj xyz -sao yup fingers_L_index1; select fingers_L_index2;
	joint -n "fingers_L_index3" -p 18.61153561 34.89041914 -1.08156486;
	joint -e -zso -oj xyz -sao yup fingers_L_index2; select L_wrist;
	joint -n "fingers_L_thumb0" -p 16.37298826 34.93391231 -1.145627045;
	joint -e -zso -oj xyz -sao yup L_wrist; select fingers_L_thumb0;
	joint -n "fingers_L_thumb1" -p 16.85188066 34.93391231 -0.8111011307;
	joint -e -zso -oj xyz -sao yup fingers_L_thumb0; select fingers_L_thumb1;
	joint -n "fingers_L_thumb2" -p 17.21583888 34.93391231 -0.5568614414;
	joint -e -zso -oj xyz -sao yup fingers_L_thumb1; select fingers_L_thumb2;
	joint -n "fingers_L_thumb3" -p 17.69473128 34.93391231 -0.2223355272;

// back
	select -cl;
	joint -n "ROOT" -p -6.162975822e-033 16.94601718 -1.186302748; select ROOT;
	joint -n "back_01" -p -9.24930039e-016 22.42172944 -0.6552236879;
	joint -e -zso -oj xyz -sao yup ROOT; select back_01;
	joint -n "back_02" -p -7.861523865e-016 28.05617884 -1.587542653;
	joint -e -zso -oj xyz -sao yup back_01; select back_02;
	joint -n "back_03" -p -7.368371669e-015 35.01084499 -1.02212264;
	joint -e -zso -oj xyz -sao yup back_02; select back_03;
	joint -n "neck_01" -p -8.513941026e-015 37.69807791 -0.6843921185;
	joint -e -zso -oj xyz -sao yup back_03; select neck_01;
	joint -n "neck_02" -p -8.661787348e-015 40.95644353 -0.6247150925;
	joint -e -zso -oj xyz -sao yup neck_01; select neck_02;
	joint -n "head" -p -7.381787892e-015 48.93904415 -0.6768659086;
	joint -e -zso -oj xyz -sao yup neck_02;

// legs
	select -cl;
	joint -n "L_hip" -p 2.878346058 15.01752313 -1.126459024; select L_hip;
	joint -n "L_knee" -p 2.878346058 9.258768459 1.577651866;
	joint -e -zso -oj xyz -sao yup L_hip; select L_knee;
	joint -n "L_ankle" -p 2.878346058 3.249633148 -1.777448683;
	joint -e -zso -oj xyz -sao yup L_knee; select L_ankle;
	joint -n "L_ball" -p 2.878346058 0.1949893647 0.8265099523;
	joint -e -zso -oj xyz -sao yup L_ankle; select L_ball;
	joint -n "L_toe" -p 2.878346058 0.1949893647 4.281762756;
	joint -e -zso -oj xyz -sao yup L_ball;
	spaceLocator -p 2.878346 0.194989 -3.416186 -n L_heel;CenterPivot;

// Locators
	spaceLocator -n fo_fingers_L_pinkey; move -ws -a 17.08191922 35.47825199 -2.847456219;scale -r 0.2 0.2 0.2;
	spaceLocator -n fo_fingers_L_ringfinger; move -ws -a 17.13548842 35.53201902 -2.201348721;scale -r 0.2 0.2 0.2;
	spaceLocator -n fo_fingers_L_middlefinger; move -ws -a 17.14833758 35.53758678 -1.786573894;scale -r 0.2 0.2 0.2;
	spaceLocator -n fo_fingers_L_index; move -ws -a 17.0364656 35.56420673 -1.425986546;scale -r 0.2 0.2 0.2;
	spaceLocator -n fo_fingers_L_thumb; move -ws -a 16.37298826 35.54665963 -0.473 ;scale -r 0.2 0.2 0.2;

	spaceLocator -n "back_upvector"; move -ws -a 0 0 1000;

	parent L_hip ROOT;
	parent L_shoulder back_03;
	select -cl;
	group -n bittnerRig3_guide ROOT L_heel;
	
	parent fo_fingers_L_pinkey fo_fingers_L_ringfinger fo_fingers_L_middlefinger fo_fingers_L_index fo_fingers_L_thumb back_upvector bittnerRig3_guide;	
	select -cl;
}


global proc br3_createQuadrupedGuide()
{
// backleg
	select -cl;
	joint -n "L_b_hip" -p 2.878346058 15.01752313 -1.126459024; select L_b_hip;
	joint -n "L_b_knee" -p 2.878346058 9.258768459 1.577651866;
	joint -e -zso -oj xyz -sao yup L_b_hip; select L_b_knee;
	joint -n "L_b_ankle" -p 2.878346058 3.249633148 -1.777448683;
	joint -e -zso -oj xyz -sao yup L_b_knee; select L_b_ankle;
	joint -n "L_b_heel" -p 2.878346058 0.1949893647 -1.145738209;
	joint -e -zso -oj xyz -sao yup L_b_ankle; select L_b_heel;
	joint -n "L_b_toe" -p 2.878346058 0.1949893647 -0.5220570104;
	joint -e -zso -oj xyz -sao yup L_b_heel;

// frontleg
	select -cl;
	joint -n "L_f_shoulder" -p 0.7843359553 17.32736828 16.84658641; select L_f_shoulder;
	joint -n "L_f_hip" -p 2.878346058 19.75753314 16.84658641;
	joint -e -zso -oj xyz -sao yup L_f_shoulder; select L_f_hip;
	joint -n "L_f_knee" -p 2.878346058 11.02788527 19.5506973;
	joint -e -zso -oj xyz -sao yup L_f_hip; select L_f_knee;
	joint -n "L_f_ankle" -p 2.878346058 3.930470711 19.29913259;
	joint -e -zso -oj xyz -sao yup L_f_knee; select L_f_ankle;
	joint -n "L_f_heel" -p 2.878346058 0.1949893647 19.16673012;
	joint -e -zso -oj xyz -sao yup L_f_ankle; select L_f_heel;
	joint -n "L_f_toe" -p 2.878346058 0.1949893647 19.79041131;
	joint -e -zso -oj xyz -sao yup L_f_heel;

// back
	select -cl;
	joint -n "ROOT" -p -6.162975822e-033 16.94601718 -1.186302748; select ROOT;
	joint -n "back_01" -p -9.24930039e-016 17.68069904 3.421036273;
	joint -e -zso -oj xyz -sao yup ROOT; select back_01;
	joint -n "back_02" -p -1.484210085e-014 16.79969226 7.863826938;
	joint -e -zso -oj xyz -sao yup back_01; select back_02;
	joint -n "back_03" -p -3.55218234e-014 16.69144855 11.9326008;
	joint -e -zso -oj xyz -sao yup back_02; select back_03;
	joint -n "neck_01" -p -4.195670181e-014 17.33235164 16.98431127;
	joint -e -zso -oj xyz -sao yup back_03; select neck_01;
	joint -n "neck_02" -p -4.722340467e-014 20.42400785 22.42475311;
	joint -e -zso -oj xyz -sao yup neck_01; select neck_02;
	joint -n "head_01" -p -6.204541479e-014 23.87295822 27.19818708;
	joint -e -zso -oj xyz -sao yup neck_02; select head_01;
	joint -n "head_02" -p -6.365025597e-014 23.87295822 34.2124588;
	joint -e -zso -oj xyz -sao yup head_01; select ROOT;
	joint -n "tail_0" -p -1.013481275e-017 16.85515725 -2.609790086;
	joint -e -zso -oj xyz -sao yup ROOT; select tail_0;
	joint -n "tail_1" -p -1.536798038e-015 16.85515725 -4.232205067;
	joint -e -zso -oj xyz -sao yup tail_0; select tail_1;
	joint -n "tail_2" -p -4.634334358e-015 16.85515725 -5.854620049;
	joint -e -zso -oj xyz -sao yup tail_1; select tail_2;
	joint -n "tail_3" -p -6.018190938e-015 16.85515725 -7.47703503;
	joint -e -zso -oj xyz -sao yup tail_2; select tail_3;
	joint -n "tail_4" -p -8.544500679e-015 16.85515725 -9.099450012;
	joint -e -zso -oj xyz -sao yup tail_3; select tail_4;
	joint -n "tail_5" -p -1.149923035e-014 16.85515725 -10.72186499;
	joint -e -zso -oj xyz -sao yup tail_4; select tail_5;
	joint -n "tail_6" -p -1.259747364e-014 16.85515725 -12.34427997;
	joint -e -zso -oj xyz -sao yup tail_5; select tail_6;
 	
 	parent L_f_shoulder neck_01;
	parent L_b_hip ROOT;
	
	group -n bittnerRig3_guide ROOT;
	select -cl;
}


global proc br3_createControll(string $object)
{
	global float $br3_size;
	$br3_size = 1;
	makectroll($object,$object,1,1,1);
}


proc blendJoints(string $IK, string $FK, string $main, string $parameter)
{
	string $tok[]; tokenize $parameter "." $tok;
	string $prefix;
	for ($t in $tok)
		$prefix = $prefix + $t;

	select $IK $FK $main;
	string $constrs[] = `orientConstraint`;
	setAttr ($constrs[0] + ".interpType") 2;

	string $mainkinder[] = `listRelatives -c -typ joint $main`;
	string $IKkinder[] = `listRelatives -c -typ joint $IK`;
	string $FKkinder[] = `listRelatives -c -typ joint $FK`;

	string $sb_div10;
	string $startrev;

	if (!size(`ls -sn ($prefix + "_sb_div10")`))
	{
		$sb_div10 = `shadingNode -asUtility multiplyDivide -n ($prefix  + "_sb_div10")`;
		connectAttr -force $parameter ($sb_div10 + ".input1X");
		setAttr ($sb_div10 + ".input2X") 0.1;
		$startrev = `shadingNode -asUtility reverse -n ($prefix  + "_sb_div10_reverse")`;
		connectAttr -force ($sb_div10 + ".outputX") ($startrev  + ".inputX");
	}
	else
	{
		$sb_div10 = ($prefix + "_sb_div10");
		$startrev = ($prefix + "_sb_div10_reverse");
	}

	connectAttr -force ($sb_div10 + ".outputX") ($constrs[0] + "." + $IK + "W0");
	connectAttr -force ($startrev + ".outputX") ($constrs[0] + "." + $FK + "W1");

	global int $br3_scaling;
	if (($br3_scaling) && (size($FKkinder)))
	{
		string $scaleblender = `shadingNode -asUtility blendColors -n ($FK + "to" + $IK + "_scaleBlender")`;
		connectAttr ($sb_div10 + ".outputX") ($scaleblender + ".blender");
		connectAttr ($IKkinder[0] + ".tx") ($scaleblender + ".color1R");
		connectAttr ($FKkinder[0] + ".tx") ($scaleblender + ".color2R");
		connectAttr ($scaleblender + ".output.outputR") ($mainkinder[0] + ".tx");
	}
}


global proc string[] br3_orientControll(int $global)
{
	string $ctrollname;
	string $sel[] = `ls -sl -et joint`;
	string $rets[];
	clear $rets;
	global float $br3_size;
	

	
	for ($i = 0;$i<size($sel);$i++)
	{	
		string $group = `group -em -n ($sel[$i] + "_rotateGroup")`;
		string $ctrollname = ("ctr_" + $sel[$i]);
		$rets[size($rets)] = $ctrollname;
		curve -d 1 -p -0.5 0 0.5 -p 0.5 0 0.5 -p 0.5 0 -0.5 -p -0.5 0 -0.5 -p -0.5 0 0.5 -p -0.4 1 0.4 
		-p -0.5 0 0.5 -p 0.5 0 0.5 -p 0.4 1 0.4 -p 0.5 0 0.5 -p 0.5 0 -0.5 -p 0.4 1 -0.4 -p 0.5 0 -0.5 
		-p -0.5 0 -0.5 -p -0.4 1 -0.4 -p -0.4 1 0.4 -p 0.4 1 0.4 -p 0.4 1 -0.4 -p -0.4 1 -0.4 -k 0 -k 1 
		-k 2 -k 3 -k 4 -k 5 -k 6 -k 7 -k 8 -k 9 -k 10 -k 11 -k 12 -k 13 -k 14 -k 15 -k 16 -k 17 -k 18 
		-n $ctrollname;
		string $kinder[] = `listRelatives -c -typ joint $sel[$i]`;
		setAttr ($ctrollname + ".sy") (float(`getAttr($kinder[0] + ".tx")`) / 1.1);
		setAttr ($ctrollname + ".sx") (float(`getAttr($kinder[0] + ".tx")`) / 3 );
		setAttr ($ctrollname + ".sz") (float(`getAttr($kinder[0] + ".tx")`) / 3 );
		setAttr ($ctrollname + ".rz") -90;
		makeIdentity -apply true -t 1 -r 1 -s 1 -n 0 $ctrollname;

		
		select $sel[$i] $ctrollname;
		string $constrs[] = `parentConstraint`;
		delete $constrs;
		select $sel[$i] $group;
		string $constrs[] = `parentConstraint`;
		delete $constrs;
		
		string $eltern[] = `listRelatives -p $sel[$i]`;
		if (size($eltern))
			parent $group $eltern[0];
			
		parent $ctrollname $group;
		
		if (!$global)
			connectAttr -f ($ctrollname + ".rotate") ($sel[$i] + ".rotate");
		
		string $params[] = {"tx", "ty", "tz", "sy", "sz"};
		for ($param in $params)
			setAttr -lock true -keyable false ($ctrollname + "." + $param);
		global int $br3_scaling;
		if (!$br3_scaling)
			setAttr -lock true -keyable false ($ctrollname + ".sx");

		if ($br3_scaling)
		{
			string $scalemultipl = `shadingNode -asUtility multiplyDivide -n ($sel[$i] + "_scaleFixing")`;
			connectAttr ($ctrollname + ".sx") ($scalemultipl + ".input2X");
			string $kinder[] = `listRelatives -c -typ joint $sel[$i]`;
			setAttr ($scalemultipl + ".input1X") `getAttr($kinder[0] + ".tx")`;

			float $testfloat = `getAttr($kinder[0] + ".tx")`;

			connectAttr ($scalemultipl + ".outputX") ($kinder[0] + ".tx");
			connectAttr -f ($sel[$i] + ".tx") ($group + ".tx");
		}

		if ($global)
		{
			string $globalgroup = `group -em -n ($ctrollname + "_globalRotateGroup")`;
			string $localgroup = `group -em -n ($ctrollname + "_localRotateGroup")`;
			string $blendgroup = `group -em -n ($ctrollname + "_blendRotateGroup")`;

			palign($sel[$i],$globalgroup);oalign($sel[$i],$globalgroup);
			palign($sel[$i],$localgroup);oalign($sel[$i],$localgroup);
			palign($sel[$i],$blendgroup);oalign($sel[$i],$blendgroup);

			parent $localgroup $eltern[0];
			select $sel[$i] $globalgroup;
			pointConstraint;
			select $sel[$i] $blendgroup;
			pointConstraint;

			select $globalgroup $localgroup $blendgroup;
			string $constrs[] = `orientConstraint`;
			setAttr ($constrs[0] + ".interpType") 2;

			addparameter($ctrollname, "global", "float");
			string $sb_div10 = `shadingNode -asUtility multiplyDivide -n "sb_div10"`;
			connectAttr -force ($ctrollname + ".global") ($sb_div10 + ".input1X");
			setAttr ($sb_div10 + ".input2X") 0.1;
			connectAttr -force ($sb_div10 + ".outputX") ($constrs[0] + "." + $globalgroup + "W0");
			string $startrev = `shadingNode -asUtility reverse -n ($sel[$i] + "_constrReverse")`;
			connectAttr -force ($sb_div10 + ".outputX") ($startrev + ".inputX");
			connectAttr -force ($startrev + ".outputX") ($constrs[0] + "." + $localgroup + "W1");
			parent $ctrollname $blendgroup;
			select $ctrollname $sel[$i];
			string $constrs[] = `orientConstraint`;
			setAttr ($constrs[0] + ".interpType") 2;
		}
	}
	return $rets;
}


proc IKScaling(string $firstjoint, string $ctroll)
{
	global string $br3_globalname;
	
	string $distance = `distanceDimension -sp 0 0 0 -ep 1 1 1`;
	string $locaters[] = `listConnections $distance`;
	palign($firstjoint, $locaters[0]);
	string $eltern[] = `listRelatives -p -typ joint $firstjoint`;
	parent $locaters[0] $eltern[0];

	string $ikHandles[] = `listConnections -t ikHandle $firstjoint`;
	palign($ikHandles[0],$locaters[1]);
	
	parent $locaters[1] $ctroll;

	addAttr -k 1 -ln autoScale -at "enum" -en "Off:On:" -min 0 $ctroll ;

	string $kinder[] = `listRelatives -c -typ joint $firstjoint`;
	string $enkel[] = `listRelatives -c -typ joint $kinder[0]`;
	float $urlength = `getAttr($kinder[0] + ".tx")` + `getAttr($enkel[0] + ".tx")`;
	if ($urlength < 0)
		$urlength = $urlength * (-1);

	string $ifanaus = `shadingNode -asUtility condition -n ($br3_globalname + "ifScaleOrNot")`;
	connectAttr ($ctroll + ".autoScale") ($ifanaus + ".firstTerm");
	setAttr ($ifanaus + ".secondTerm") 1;
	connectAttr ($distance + ".distance") ($ifanaus + ".colorIfTrueR");
	setAttr ($ifanaus + ".colorIfFalseR") $urlength;

	string $scalemultipl = `shadingNode -asUtility multiplyDivide -n ($br3_globalname + "scaleMultipl")`;

	string $clamp = `shadingNode -asUtility clamp -n ($br3_globalname + "scaleClamp")`;
	connectAttr ($ifanaus + ".outColorR") ($clamp + ".inputR");
	connectAttr -force ($clamp + ".outputR") ($scalemultipl + ".input1X");
	setAttr ($clamp + ".minR") $urlength;
	setAttr ($clamp + ".maxR") 10000000;

	setAttr ($scalemultipl + ".input2X") $urlength;
	setAttr ($scalemultipl + ".operation") 2;

	string $mjoint1 = `shadingNode -asUtility multiplyDivide -n ($br3_globalname + "scaleMultipl_01")`;
	string $mjoint2 = `shadingNode -asUtility multiplyDivide -n ($br3_globalname + "scaleMultipl_02")`;
	connectAttr -force ($scalemultipl + ".outputX") ($mjoint1 + ".input1X");
	connectAttr -force ($scalemultipl + ".outputX") ($mjoint2 + ".input1X");
	setAttr ($mjoint1 + ".input2X") `getAttr($kinder[0] + ".tx")`;
	setAttr ($mjoint2 + ".input2X") `getAttr($enkel[0] + ".tx")`;
	connectAttr -force ($mjoint1 + ".outputX") ($kinder[0] + ".tx");
	connectAttr -force ($mjoint2 + ".outputX") ($enkel[0] + ".tx");

	hideObjs{$distance, $locaters[0], $locaters[1]};
	
	string $eltern[] = `listRelatives -p -typ transform $distance`;
	rename $eltern[0] ("br3_distancetool_" + $br3_globalname);

}



proc string[] makeIKchain (string $firstjoint, string $endjoint)
{
	global float $br3_size;
	global string $br3_globalname;

	select ($firstjoint + ".rotatePivot") ($endjoint + ".rotatePivot");
	string $thehandle[] = `ikHandle -n ("br3_ikHandle_" + $endjoint)`;
	hideObjs{$thehandle[0]};

	string $ctrollname = "ctrIK_" + $br3_globalname;
	makectroll($ctrollname,"cube",5,5,5);
	palign($endjoint,$ctrollname);
	makeIdentity -a 1 -t 1 $ctrollname;
	select $ctrollname $thehandle[0];
	pointConstraint;

	string $kinder[] = `listRelatives -c -typ joint $firstjoint`;

	string $polevectorname = ("ctr_" + $br3_globalname + "_polevector");

	makectroll($polevectorname,"sphere",3,3,3);

	select $firstjoint $endjoint $polevectorname;
	string $constrs[] = `pointConstraint`;
	delete $constrs;
	string $kinder[] = `listRelatives -c -typ "joint" $firstjoint`;
	select $kinder[0] $polevectorname;
	string $constrs[] = `aimConstraint`;
	delete $constrs;
	move -r -os -wd (10 * $br3_size) 0 0 $polevectorname ;
	makeIdentity -a 1 -t 1 $polevectorname;

	select $polevectorname $thehandle[0];
	poleVectorConstraint;
	
	global int $br3_scaling;
	
	if ($br3_scaling)
		IKScaling($firstjoint, $ctrollname);
	
	return {$ctrollname,$polevectorname,$thehandle[0]};
}


proc string antiParent(string $obj)
{
	string $eltern[] = `listRelatives -p $obj`;
	string $group = `group -em -n ("antiParentGroup" + $obj)`;
	select $eltern[0] $group;
	parentConstraint;
	parent $obj $group;
	return $group;
}



proc string[] globalMove(string $obj)
{
	select $obj;
	string $blendgroup = `group -n ($obj + "_blendTranslateGroup")`;
	CenterPivot $blendgroup;
	select -d;
	string $localgroup = `group -em -n ($obj + "_localTranslateGroup")`;
	string $globalgroup = `group -em -n ($obj + "_globalTranslateGroup")`;
	palign($blendgroup, $localgroup);oalign($blendgroup, $localgroup);
	palign($blendgroup, $globalgroup);oalign($blendgroup, $globalgroup);
	select $globalgroup $localgroup $blendgroup;
	string $constrs[] = `parentConstraint`;

	addparameter($obj, "global", "float");
	string $sb_div10 = `shadingNode -asUtility multiplyDivide -n "sb_div10"`;
	connectAttr -force ($obj + ".global") ($sb_div10 + ".input1X");
	setAttr ($sb_div10 + ".input2X") 0.1;
	connectAttr -force ($sb_div10 + ".outputX") ($constrs[0] + "." + $globalgroup + "W0");
	string $startrev = `shadingNode -asUtility reverse -n ($obj + "_globalMoveReverse")`;
	connectAttr -force ($sb_div10 + ".outputX") ($startrev + ".inputX");
	connectAttr -force ($startrev + ".outputX") ($constrs[0] + "." + $localgroup + "W1");

	return {$localgroup, $globalgroup};
}




proc inbetweenjoints(string $startjoint, string $endjoint, int $number, int $twister)
{
	if ($number)
	{
		string $lastjoint = "";
		float $length = `getAttr($endjoint + ".tx")`;
		string $finaljoints[];
		clear $finaljoints;
		select -cl;

		for ($i = 0;$i < ($number + 1);$i++)
		{
			string $newjoint = `joint -p ($length * float($i)/$number) 0 0 -n ($startjoint + "_inbetween_" + $i)`;
			$finaljoints[size($finaljoints)] = $newjoint;
			if (size($lastjoint))
				joint -e -zso -oj xyz -sao yup $lastjoint;
			$lastjoint = $newjoint;

		}
		parent $finaljoints[0] $startjoint;
		string $params[] = {"tx", "ty", "tz", "rx", "ry", "rz", "jointOrientX", "jointOrientY", "jointOrientZ"};
		for ($param in $params)
			setAttr ($finaljoints[0] + "." + $param) 0;

		if (!$twister)
		{
			string $negmultipl = `shadingNode -asUtility multiplyDivide -n ($startjoint + "inbetweenjoints_negmultipl")`;
			connectAttr ($startjoint + ".rx") ($negmultipl + ".input1X");
			setAttr ($negmultipl + ".input2X") -1;
			connectAttr ($negmultipl + ".outputX") ($finaljoints[0] + ".rx");
		}

		string $bruchmultipl = `shadingNode -asUtility multiplyDivide -n ($startjoint + "inbetweenjoints_part")`;
		if (!$twister)
			connectAttr -force ($startjoint + ".rx") ($bruchmultipl + ".input1X");
		else
			connectAttr -force ($endjoint + ".rx") ($bruchmultipl + ".input1X");

		setAttr ($bruchmultipl + ".input2X") (float(1)/$number);

		for ($i = 1;$i < size($finaljoints);$i++)
			connectAttr ($bruchmultipl + ".outputX") ($finaljoints[$i] + ".rx");

		antiParent($finaljoints[0]);

		global int $br3_scaling;
		if ($br3_scaling)
		{
			string $scalefactor = `shadingNode -asUtility multiplyDivide -n ($startjoint + "_inbetweenscalefactor")`;
			if (`getAttr($endjoint + ".tx")` > 0)
				setAttr ($scalefactor + ".input2X") `getAttr($endjoint + ".tx")`;
			else
				setAttr ($scalefactor + ".input2X") (`getAttr($endjoint + ".tx")` * -1);
			connectAttr ($endjoint + ".tx") ($scalefactor + ".input1X");
			setAttr ($scalefactor + ".operation") 2;
			string $jointscaler = `shadingNode -asUtility multiplyDivide -n ($startjoint + "_inbetweenscaleeachjoint")`;
			setAttr ($jointscaler + ".input1X") `getAttr($finaljoints[1] + ".tx")`;
			connectAttr ($scalefactor + ".outputX") ($jointscaler + ".input2X");
			for ($i = 1;$i<size($finaljoints);$i++)
				connectAttr ($jointscaler + ".outputX") ($finaljoints[$i] + ".tx");
		}
	}

}

proc string[] createikSpline(int $curveOrJoints, string $curve, string $firstjoint, string $endjoint, string $newjointname)
{
	global int $br3_sameTx2;
	global int $br3_scaling;
	global string $br3_globalname;
	global int $br3_scaleByT;
	
	if ($curveOrJoints)
	{
		string $locs[] = `spaceLocator`;
		select $locs[0] $curve;
		string $pathanim = `pathAnimation -fractionMode true -follow true -followAxis x -upAxis y -worldUpType "vector" -worldUpVector 0 1 0 -inverseUp false -inverseFront false -bank false`;
		setAttr ($pathanim + ".uValue") 0;

		select -cl;

		float $locpos[2] = `xform -q -ws -t $locs[0]`;
		string $newjoint = `joint -n ($newjointname + "_chain")  -p $locpos[0] $locpos[1] $locpos[2]`;
		string $lastjoint = $newjoint;
		$firstjoint = $newjoint;

		int $anzahl = `intSliderGrp -q -v br3_ikSplineByCurveAnzahlDerJoints`;
		
		string $alljoints[];
		for ($i = 0;$i < ($anzahl);$i++)
		{
			$wert = (float($i) / $anzahl + float(1)/$anzahl);
			setAttr ($pathanim + ".uValue") $wert;
			float $locpos[2] = `xform -q -ws -t $locs[0]`;
			string $newjoint = `joint -n ($newjointname + "_" + $i) -p $locpos[0] $locpos[1] $locpos[2]`;
			joint -e -zso -oj xyz -sao yup $lastjoint;
			$lastjoint = $newjoint;

			$endjoint = $lastjoint;
			$alljoints[size($alljoints)] = $lastjoint;
			refresh;
		}
		delete $locs;
	}

	select ($firstjoint + ".rotatePivot") ($endjoint + ".rotatePivot");
	string $thehandle[] = `ikHandle -sol ikSplineSolver -ns 2`;
	
	if ($curveOrJoints)
	{
		string $col[] = `ls -dag $curve`;
		string $curveshape = $col[1];
		connectAttr -force ($curveshape + ".worldSpace[0]") ($thehandle[0] + ".inCurve");
		delete $thehandle[2];
	}
	else
	{
		$thehandle[2] = `rename $thehandle[2] ("br3_splineHandleCurve")`;
		$curve = $thehandle[2];

	}
		$thehandle[0] = `rename $thehandle[0] ("br3_splineHandle")`;


	if ($br3_scaling)
	{
		string $cin = `arclen -ch 1 $curve`;
		string $mm = `shadingNode -asUtility multiplyDivide -n getScaleFactor`;
		connectAttr -force ($cin + ".arcLength") ($mm + ".input1X");	
		setAttr ($mm + ".input2X") `getAttr($mm + ".input1X")`;
		setAttr ($mm + ".operation") 2;
	
		string $jointlist[] = `ikHandle -q -jl $thehandle[0]`;
		
		if ($br3_scaleByT)
			for ($i = 0;$i < (size($jointlist));$i++)
				connectAttr -force ($mm + ".outputX") ($jointlist[$i] + ".scaleX");								
		else
		{
			if ($br3_sameTx2)
			{		
				string $sametxmultipl = `shadingNode -asUtility multiplyDivide -n ($firstjoint + "translateX_multipl")`;
				connectAttr -force ($mm + ".outputX") ($sametxmultipl + ".input1X");
				setAttr ($sametxmultipl + ".input2X") `getAttr ($jointlist[1] + ".translateX")`;
				for ($i = 0;$i<size($jointlist);$i++)
					connectAttr -force ($sametxmultipl + ".outputX") ($jointlist[$i] + ".translateX");
				
				string $kinder[] = `listRelatives -c -typ "joint" $jointlist[$i - 1]`;
				connectAttr -force ($sametxmultipl + ".outputX") ($kinder[0] + ".translateX");
				
			}
			else
			{
				for ($i = 0;$i < (size($jointlist));$i++)
				{
					string $multipl = `shadingNode -asUtility multiplyDivide -n ($jointlist[$i] + "_translatemultipl")`;				
					connectAttr -force ($mm + ".outputX") ($multipl + ".input1X");								
					setAttr ($multipl + ".input2X") `getAttr($jointlist[$i] + ".translateX")`;
					connectAttr -force ($multipl + ".outputX") ($jointlist[$i] + ".translateX");
				}
				string $kinder[] = `listRelatives -c -typ "joint" $jointlist[$i - 1]`;
				string $multipl = `shadingNode -asUtility multiplyDivide -n ($kinder[0] + "_translatemultipl")`;				
				connectAttr -force ($mm + ".outputX") ($multipl + ".input1X");								
				setAttr ($multipl + ".input2X") `getAttr($kinder[0] + ".translateX")`;
				connectAttr -force ($multipl + ".outputX") ($kinder[0] + ".translateX");
			}
		}
	}
	return {$curve, $thehandle[0]};
}



global proc br3_createikSplineButton()
{
	global int $br3_sameTx2;
	global int $br3_scaling;
	global string $br3_globalname;
	global int $br3_scaleByT;
	
	$br3_sameTx2 = `checkBox -q -v chbx_br3_sametranslateXSpline`;
	$br3_scaling = `checkBox -q -v chbx_br3_scalejointsSpline`;
	
	int $curveOrJoints = `checkBox -q -v br3_splineHandleByCurveOrNot`;
	string $curve = `textFieldButtonGrp -q -text br3_splineRig_curve`;
	string $startjoint = `textFieldButtonGrp -q -text br3_splineRig_startJoint`;
	string $endjoint = `textFieldButtonGrp -q -text br3_splineRig_endJoint`;
	string $newjointname = `textField -q -tx br3_iksplinehandlejointname`;
	createikSpline($curveOrJoints, $curve, $startjoint, $endjoint, $newjointname);
}



proc string[] createBackIK(string $backjoints[], string $IKback[], string $IKdummyback[], string $otherjoints[], string $rootcontroll)
{
	global string $br3_globalname;
	global int $br3_scaling;
	global int $br3_biped;
	
	string $ikCurve[] = `createikSpline 0 " " $IKback[0] $IKback[size($IKback) - 1] " "`;
	for ($i = 0;$i<size($backjoints);$i++)
	{
		select $IKback[$i] $IKdummyback[$i];
		orientConstraint -mo -weight 1;
		connectAttr ($IKback[$i] + ".tx") ($IKdummyback[$i] + ".tx");
	}
	hideObjs($ikCurve);
	parent -w $ikCurve[0];

	select -r ($ikCurve[0] + ".cv[0:1]");
	string $cluster1[] = `newCluster " -envelope 1"`;
	select -r ($ikCurve[0] + ".cv[2]");
	string $cluster2[] = `newCluster " -envelope 1"`;
	select -r ($ikCurve[0] + ".cv[3:4]");
	string $cluster3[] = `newCluster " -envelope 1"`;

	string $dupls[] = `duplicate -rc $backjoints[0]` ;
	string $kinder[] = `listRelatives -c -typ joint $dupls[0]`;
	delete $kinder;
	string $addjoint = $dupls[0];
	for ($i = 0;$i<size($otherjoints);$i++)
		if ($otherjoints[$i] != "rightone")
			parent $otherjoints[$i] $addjoint;
	$addjoint = `rename $addjoint ($backjoints[0] + "_addjoint")`;		

	string $hipcontroll = "ctr_" + $br3_globalname + "_hip";
	string $backcontroll = "ctr_" + $br3_globalname + "_back";
	string $chestcontroll = "ctr_" + $br3_globalname + "_chest";
	makectroll($hipcontroll, "square",10, 10, 10);		
	makectroll($backcontroll, "square",10, 10, 10);		
	makectroll($chestcontroll, "square",10, 10, 10);

	if (!$br3_biped)
	{
		setAttr ($backcontroll + ".rx") 90;
		setAttr ($chestcontroll + ".rx") 90;
		setAttr ($hipcontroll + ".rx") 90;
	}
	
	palign($backjoints[0], $hipcontroll);
	palign($cluster2[1], $backcontroll);
	palign($backjoints[size($backjoints) - 1], $chestcontroll);

	parent $hipcontroll $rootcontroll;
	parent $cluster1[1] $addjoint $IKback[0] $hipcontroll;
	parent $cluster2[1] $backcontroll;
	parent $cluster3[1] $chestcontroll;
	string $groups[] = `globalMove $chestcontroll`;
	parent $groups[0] $rootcontroll;
	string $groups[] = `globalMove $backcontroll`;
	parent $groups[0] $rootcontroll;

	string $params[] = {"tx", "ty", "tz", "sx", "sy", "sz"};
	for ($param in $params)
		setAttr -lock true -keyable false ($hipcontroll + "." + $param);
	string $params[] = {"rx", "ry", "rz", "sx", "sy", "sz"};
	for ($param in $params)
		setAttr -lock true -keyable false ($backcontroll + "." + $param);


	string $substract = `shadingNode -asUtility plusMinusAverage`;
	if ($br3_biped)
	{
		connectAttr ($chestcontroll + ".ry") ($substract + ".input1D[0]");
		connectAttr ($hipcontroll + ".ry") ($substract + ".input1D[1]");
	}
	else 
	{
		connectAttr ($chestcontroll + ".rz") ($substract + ".input1D[0]");
		connectAttr ($hipcontroll + ".rz") ($substract + ".input1D[1]");
	}
	setAttr ($substract + ".operation") 2;
	connectAttr -force ($substract + ".output1D") ($ikCurve[1] + ".twist");

	if ($br3_scaling)
	{
		string $locs[] = `spaceLocator -p 0 0 0`;
		palign($chestcontroll, $locs[0]);
		parent $locs[0] $chestcontroll;
		delete `listRelatives -c -typ orientConstraint $IKdummyback[size($IKdummyback) - 2]`;
		select $locs[0] $IKdummyback[size($IKdummyback) - 2];
		string $aimConstrs[] = `aimConstraint -skip x`;
		select $locs[0] $IKdummyback[size($IKdummyback) - 1];
		pointConstraint;
		connectAttr ($IKback[size($IKback) - 2] + ".rx") ($IKdummyback[size($IKdummyback) - 2] + ".rx");
		
	//chest
		string $ikgroup = `group -em -n "br3_backIKgroup"`;
		string $fkgroup = `group -em -n "br3_backFKgroup"`;
		oalign($backjoints[size($backjoints) - 1], $ikgroup);
		oalign($backjoints[size($backjoints) - 1], $fkgroup);
		parent $ikgroup $locs[0];
		parent $fkgroup $backjoints[size($backjoints) - 2];
		select $ikgroup $fkgroup $backjoints[size($backjoints) - 1];
		string $constrs[] = `orientConstraint`;
		string $sb_div10 = `shadingNode -asUtility multiplyDivide -n "sb_div10"`;
		connectAttr -force ("settings_" + $br3_globalname + ".IK_FK_blend") ($sb_div10 + ".input1X");
		setAttr ($sb_div10 + ".input2X") 0.1;
		connectAttr -force ($sb_div10 + ".outputX") ($constrs[0] + "." + $ikgroup + "W0");
		string $startrev = `shadingNode -asUtility reverse -n ("back_constrReverse")`;
		connectAttr -force ($sb_div10 + ".outputX") ($startrev + ".inputX");
		connectAttr -force ($startrev + ".outputX") ($constrs[0] + "." + $fkgroup + "W1");	
	}
	return {$rootcontroll, $hipcontroll, $backcontroll, $chestcontroll};
}


proc string createBackIKONLY(string $IKback[], string $IKdummyback[], string $otherjoints[], string $rootcontroll)
{
	global string $br3_globalname;
	global int $br3_scaling;
	global int $br3_biped;

	
	string $ikCurve[] = `createikSpline 0 " " $IKback[0] $IKback[size($IKback) - 1] " "`;
	for ($i = 0;$i<size($IKdummyback);$i++)
	{
		select $IKback[$i] $IKdummyback[$i];
		orientConstraint -mo -weight 1;
		connectAttr ($IKback[$i] + ".tx") ($IKdummyback[$i] + ".tx");
	}
	hideObjs($ikCurve);
	parent -w $ikCurve[0];

	select -r ($ikCurve[0] + ".cv[0:1]");
	string $cluster1[] = `newCluster " -envelope 1"`;
	select -r ($ikCurve[0] + ".cv[2]");
	string $cluster2[] = `newCluster " -envelope 1"`;
	select -r ($ikCurve[0] + ".cv[3:4]");
	string $cluster3[] = `newCluster " -envelope 1"`;

	string $dupls[] = `duplicate -rc $IKdummyback[0]` ;
	string $kinder[] = `listRelatives -c -typ joint $dupls[0]`;
	delete $kinder;
	string $addjoint = $dupls[0];
	for ($i = 0;$i<size($otherjoints);$i++)
		if ($otherjoints[$i] != "rightone")
			parent $otherjoints[$i] $addjoint;
	$addjoint = `rename $addjoint ($IKdummyback[0] + "_addjoint")`;		

	string $hipcontroll = "ctr_" + $br3_globalname + "_hip";
	string $backcontroll = "ctr_" + $br3_globalname + "_back";
	string $chestcontroll = "ctr_" + $br3_globalname + "_chest";
	makectroll($hipcontroll, "square",10, 10, 10);		
	makectroll($backcontroll, "square",10, 10, 10);		
	makectroll($chestcontroll, "square",10, 10, 10);
	if (!$br3_biped)
	{
		setAttr ($backcontroll + ".rx") 90;
		setAttr ($chestcontroll + ".rx") 90;
		setAttr ($hipcontroll + ".rx") 90;
	}

	palign($IKdummyback[0], $hipcontroll);
	palign($cluster2[1], $backcontroll);
	palign($IKdummyback[size($IKdummyback) - 1], $chestcontroll);

	parent $hipcontroll $rootcontroll;
	parent $cluster1[1] $addjoint $IKback[0] $hipcontroll;
	parent $cluster2[1] $backcontroll;
	parent $cluster3[1] $chestcontroll;
	string $groups[] = `globalMove $chestcontroll`;
	parent $groups[0] $rootcontroll;
	string $groups[] = `globalMove $backcontroll`;
	parent $groups[0] $rootcontroll;

	string $params[] = {"tx", "ty", "tz", "sx", "sy", "sz"};
	for ($param in $params)
		setAttr -lock true -keyable false ($hipcontroll + "." + $param);
	string $params[] = {"rx", "ry", "rz", "sx", "sy", "sz"};
	for ($param in $params)
		setAttr -lock true -keyable false ($backcontroll + "." + $param);

	string $substract = `shadingNode -asUtility plusMinusAverage`;
	if ($br3_biped)
	{
		connectAttr ($chestcontroll + ".ry") ($substract + ".input1D[0]");
		connectAttr ($hipcontroll + ".ry") ($substract + ".input1D[1]");
	}
	else 
	{
		connectAttr ($chestcontroll + ".rz") ($substract + ".input1D[0]");
		connectAttr ($hipcontroll + ".rz") ($substract + ".input1D[1]");
	}
	setAttr ($substract + ".operation") 2;
	connectAttr -force ($substract + ".output1D") ($ikCurve[1] + ".twist");

	string $locs[] = `spaceLocator -p 0 0 0`;
	palign($chestcontroll, $locs[0]);
	parent $locs[0] $chestcontroll;
	if ($br3_scaling)
	{
		delete `listRelatives -c -typ orientConstraint $IKdummyback[size($IKdummyback) - 2]`;
		select $locs[0] $IKdummyback[size($IKdummyback) - 2];
		string $aimConstrs[] = `aimConstraint -skip x`;
		select $locs[0] $IKdummyback[size($IKdummyback) - 1];
		pointConstraint;
		connectAttr ($IKback[size($IKback) - 2] + ".rx") ($IKdummyback[size($IKdummyback) - 2] + ".rx");
	}

	string $ikgroup = `group -em -n "br3_IKgroup_back"`;
	oalign($IKdummyback[size($IKdummyback) - 1], $ikgroup);
	palign($IKdummyback[size($IKdummyback) - 1], $ikgroup);
	parent $ikgroup $locs[0];
	select $ikgroup $IKdummyback[size($IKdummyback) - 1];
	string $constrs[] = `orientConstraint -mo`;
	setAttr ($constrs[0] + ".interpType") 0;

	return $rootcontroll;
}



proc createBackRig(string $startjoint, string $endjoint)
{
	global int $br3_fk;
	global int $br3_ik;
	global int $br3_scaling;
	global string $br3_globalname;

	global float $br3_size;
	$br3_size = float(`getDistance $startjoint $endjoint`) / 30;
	
	string $hierjoints[] = `ls -et joint -dag $startjoint`;
	string $backjoints[];
	
	for ($i = 0;$i<size($hierjoints);$i++)
	{
		$backjoints[size($backjoints)] = $hierjoints[$i];
		if ($hierjoints[$i] == $endjoint)
			break;
	}

	$settings = ("settings_" + $br3_globalname);
	makectroll($settings, "kreuz", 3,3,3);
	palign($backjoints[size($backjoints) - 1], $settings);
	addAttr -k 1 -ln IK_FK_blend -at double  -min 0 -max 10 -dv 0 $settings;
	
	string $rootcontroll = "ctr_" + $br3_globalname + "_root";
	makectroll($rootcontroll, "cube",16, 16, 1);
	palign($backjoints[0], $rootcontroll);
	parent $backjoints[0] $rootcontroll;
	
	if (($br3_fk) && (!$br3_ik))
	{
		select -d;
		for ($i = 1;$i < (size($backjoints) - 1);$i++)
			select -add $backjoints[$i];
		br3_orientControll(0);
	}
	
	if (($br3_fk) && ($br3_ik))
	{
		string $FKback[];
		string $IKback[];
		string $IKdummyback[];
		
		string $dupls[] = `duplicate -rc $backjoints[0]`;	
		delete `listRelatives -c -typ joint $dupls[size($backjoints) - 1]`;
		for ($i = 0;$i < size($backjoints);$i++)
			$FKback[$i] = `rename $dupls[$i] ("FK" + $backjoints[$i])`;
		
		string $dupls[] = `duplicate -rc $backjoints[0]`;		
		delete `listRelatives -c -typ joint $dupls[size($backjoints) - 1]`;		
		for ($i = 0;$i < size($backjoints);$i++)
			$IKback[$i] = `rename $dupls[$i] ("IK" + $backjoints[$i])`;	
		
		string $dupls[] = `duplicate -rc $backjoints[0]`;		
		delete `listRelatives -c -typ joint $dupls[size($backjoints) - 1]`;		
		for ($i = 0;$i < size($backjoints);$i++)
			$IKdummyback[$i] = `rename $dupls[$i] ("IKdummy" + $backjoints[$i])`;	

		string $kinder[] = `listRelatives -c -typ joint $backjoints[0]`;
		string $IKkinder[] = `listRelatives -c -typ joint $IKback[0]`;
		string $FKkinder[] = `listRelatives -c -typ joint $FKback[0]`;
		string $IKdummykinder[] = `listRelatives -c -typ joint $IKdummyback[0]`;
		for ($k = 0;$k < size($kinder);$k++)
		{
			string $dagobjs[] = `ls -et joint -dag $kinder[$k]`;
			for ($i = 0;$i<size($dagobjs);$i++)
				if ($dagobjs[$i] == $backjoints[size($backjoints) - 1])
					$kinder[$k] = "rightone";
			if ($kinder[$k] != "rightone")
				delete $FKkinder[$k] $IKkinder[$k] $IKdummykinder[$k];
		}
		string $otherjoints[] = $kinder;

	// FK...
		select -d;
		for ($i = 0;$i < (size($FKback) - 1);$i++)
			select -add $FKback[$i];
		string $fkcontrolls[] = `br3_orientControll 0`;
		hideObjs{$FKback[0]};
		for ($fkcontroll in $fkcontrolls)
		{
			string $eltern[] = `listRelatives -p $fkcontroll`;
			antiParent($eltern[0]);
		}
		
	// IK...
		string $ikcontrolls[] = `createBackIK $backjoints $IKback $IKdummyback $otherjoints $rootcontroll`;
		string $eltern[] = `listRelatives -p $fkcontrolls[0]`;

		for ($i = 0;$i < (size($backjoints) - 1);$i++)
			blendJoints($IKdummyback[$i], $FKback[$i], $backjoints[$i], ($settings + ".IK_FK_blend"));
		hideObjs{$IKback[0], $IKdummyback[0]};
	
	// visibility
		addAttr -ln "vis_FK" -k 1 -at "enum" -en "off:on:" -dv 1 ("settings_" + $br3_globalname) ;
		for ($fkcontroll in $fkcontrolls)
			connectAttr ("settings_" + $br3_globalname + ".vis_FK") ($fkcontroll + ".v");
		addAttr -ln "vis_IK" -k 1 -at "enum" -en "off:on:" -dv 0 ("settings_" + $br3_globalname) ;
		for ($i = 2;$i<size($ikcontrolls);$i++)
			connectAttr ("settings_" + $br3_globalname + ".vis_IK") ($ikcontrolls[$i] + ".v");
			

	}

	if ((!$br3_fk) && ($br3_ik))
	{
		string $IKback[];

		string $dupls[] = `duplicate -rc $backjoints[0]`;		
		delete `listRelatives -c -typ joint $dupls[size($backjoints) - 1]`;		
		for ($i = 0;$i < size($backjoints);$i++)
			$IKback[$i] = `rename $dupls[$i] ("IK" + $backjoints[$i])`;	

		string $kinder[] = `listRelatives -c -typ joint $backjoints[0]`;
		string $IKkinder[] = `listRelatives -c -typ joint $IKback[0]`;
		for ($k = 0;$k < size($kinder);$k++)
		{
			string $dagobjs[] = `ls -et joint -dag $kinder[$k]`;
			for ($i = 0;$i<size($dagobjs);$i++)
				if ($dagobjs[$i] == $backjoints[size($backjoints) - 1])
					$kinder[$k] = "rightone";
			if ($kinder[$k] != "rightone")
				delete $IKkinder[$k];

		}	
		string $otherjoints[] = $kinder;
		createBackIKONLY($IKback, $backjoints, $otherjoints, $rootcontroll);
		hideObjs{$IKback[0]};
	}
}


global proc br3_createbackRig_Button()
{
	global int $br3_fk;
	global int $br3_ik;
	global int $br3_scaling;
	$br3_fk = `checkBox -q -v br3_backRig_FK`;
	$br3_ik = `checkBox -q -v br3_backRig_IK`;
	$br3_scaling = `checkBox -q -v br3_backRig_scaling`;
	global string $br3_globalname;
	$br3_globalname = "newBack";
	
	string $startjoint = `textFieldButtonGrp -q -tx br3_backRig_startJoint`;
	string $endjoint = `textFieldButtonGrp -q -tx br3_backRig_endJoint`;

	createBackRig($startjoint, $endjoint);
}


proc createArmRig(string $startjoint, string $endjoint)
{
	string $mjoint;
	string $mjoint1;
	string $mjoint2;
	string $kinder[] = `listRelatives -c -typ "joint" $startjoint`;
	string $middlejoint = $kinder[0];
	string $IKctr;
	string $IKctrpolev;
	string $settings = "";
	
	global string $br3_globalname;
	global float $br3_size;
	$br3_size = float(`getDistance $startjoint $endjoint`) / 30;
	
	global int $br3_fk;
	global int $br3_ik;
	global int $br3_scaling;
	global int $br3_utwist;
	global int $br3_ltwist;
	
	//settings
	$settings = ("settings_" + $br3_globalname);
	makectroll($settings, "kreuz", 3,3,3);
	palign($middlejoint, $settings);
	setAttr ($settings + ".tz") (`getAttr($settings + ".tz")`- (50 * $br3_size));

	
	if (($br3_fk) && (!$br3_ik))
	{
		select $startjoint;
		br3_orientControll(1);
		select $middlejoint;
		br3_orientControll(0);
	
	}
	
	if (($br3_ik) && (!$br3_fk))
	{
		string $ctrs[] = `makeIKchain $startjoint $endjoint `;
		$IKctr = $ctrs[0];
		$IKctrpolev = $ctrs[1];
		string $groups[] = `globalMove $IKctr`;
		string $eltern[] = `listRelatives -p $startjoint`;
		parent $groups[0] $eltern[0];
	}
	
	if (($br3_fk) && ($br3_ik))
	{
		addparameter($settings, "IK_FK_blend", "float");

		string $dupls[] = `duplicate -rc $startjoint`;
		if (size($dupls) > 3) 
			for ($i = 3;$i<size($dupls);$i++)
			{
				if (`objExists $dupls[$i]`)
					delete $dupls[$i];
			}
		string $IKstart = `rename $dupls[0] ($startjoint + "_IK")`;
		string $IKmiddle = `rename $dupls[1] ($middlejoint + "_IK")`;
		string $IKend = `rename $dupls[2] ($endjoint + "_IK")`;
		string $ctrs[] = `makeIKchain $IKstart $IKend`;
		$IKctr = $ctrs[0];
		$IKctrpolev = $ctrs[1];
		
		string $groups[] = `globalMove $IKctr`;
		string $eltern[] = `listRelatives -p $startjoint`;
		parent $groups[0] $eltern[0];

		string $dupls[] = `duplicate -rc $startjoint`;
		if (size($dupls) > 3)
			for ($i = 3;$i<size($dupls);$i++)
			{
				if (`objExists $dupls[$i]`)
					delete $dupls[$i];
			}

		string $FKstart = `rename $dupls[0] ($startjoint + "_FK")`;
		string $FKmiddle = `rename $dupls[1] ($middlejoint + "_FK")`;
		string $FKend = `rename $dupls[2] ($endjoint + "_FK")`;

		select $FKstart;
		string $startFKctr[] = `br3_orientControll 1`;
		select $FKmiddle;
		string $middleFKctr[] = `br3_orientControll 0`;
		
		blendJoints($IKstart, $FKstart, $startjoint, ($settings + ".IK_FK_blend"));
		blendJoints($IKmiddle, $FKmiddle, $middlejoint, ($settings + ".IK_FK_blend"));

	// hide chains
		hideObjs{$IKstart,$FKstart};
		string $eltern[] = `listRelatives -p $middleFKctr[0]`;
		antiParent($eltern[0]);
		
		addAttr -ln "vis_FK" -k 1 -at "enum" -en "off:on:" -dv 1 ("settings_" + $br3_globalname) ;
		addAttr -ln "vis_IK" -k 1 -at "enum" -en "off:on:" -dv 0 ("settings_" + $br3_globalname) ;
		for ($i = 0;$i<(size($ctrs) - 1);$i++)
			connectAttr ("settings_" + $br3_globalname + ".vis_IK") ($ctrs[$i] + ".v");
		string $fkcontrolls[] = {$startFKctr[0], $middleFKctr[0]};
		for ($ctr in $fkcontrolls)
			connectAttr ("settings_" + $br3_globalname + ".vis_FK") ($ctr + ".v");
	}

// wrist

	select $endjoint;
	string $wristctr[] = `br3_orientControll(1)`;

	if ($br3_ik)
	{
		addparameter($settings,"IK_wrist_ctr","float");
		oalign($endjoint,$IKctr);
		select $IKctr $wristctr[0] $endjoint;
		string $constrs[] = `orientConstraint`;
		setAttr ($constrs[0] + ".interpType") 2;

		string $sb_div10 = `shadingNode -asUtility multiplyDivide -n "sb_div10"`;
		connectAttr -force ($settings + ".IK_wrist_ctr") ($sb_div10 + ".input1X");
		setAttr ($sb_div10 + ".input2X") 0.1;
		connectAttr -force ($sb_div10 + ".outputX") ($constrs[0] + "." + $IKctr + " W1");
		string $startrev = `shadingNode -asUtility reverse`;
		connectAttr -force ($sb_div10 + ".outputX") ($startrev + ".inputX");
		connectAttr -force ($startrev + ".outputX") ($constrs[0] + "." + $wristctr[0] + "W0");
	}

	//inbetweenjoints
	//string $flippingavoider = settings_joint2.flipmover
	if ($br3_utwist)
		inbetweenjoints($startjoint,$middlejoint,$br3_utwist,0);
	if ($br3_ltwist)
		inbetweenjoints($middlejoint,$endjoint,$br3_ltwist,1);
	addAttr -ln upperarm_flipmover -k 1 -at "enum" -en "flip1:flip2:flip3:flip4:"  $settings;
	string $flipcalculator = `shadingNode -asUtility multiplyDivide -n "flipcalculator"`;
	connectAttr ($settings + ".upperarm_flipmover") ($flipcalculator + ".input1X");
	setAttr ($flipcalculator + ".input2X") 90;

	//connectAttr ($flipcalculator + ".outputX") ($FKstart + ".jox");
	//connectAttr ($flipcalculator + ".outputX") ($IKstart + ".jox");
	//connectAttr ($flipcalculator + ".outputX") ($startjoint + ".jox");

	string $conns[] = `listConnections -scn 1 -t multiplyDivide -p 1 -s 0 $startjoint`;
	if (size($conns))
	{
		string $addflipavoid;
		$addflipavoid = `shadingNode -asUtility plusMinusAverage`;
		connectAttr -force ($startjoint + ".rx") ($addflipavoid + ".input1D[0]");
		connectAttr -force ($flipcalculator + ".outputX") ($addflipavoid + ".input1D[1]");
		for ($conn in $conns)	
			connectAttr -force ($addflipavoid + ".output1D") $conn;
	}
}


global proc br3_createArmRig_Button()
{
	string $startjoint = `textFieldButtonGrp -q -tx br3_armRig_startJoint`;
	string $endjoint = `textFieldButtonGrp -q -tx br3_armRig_endJoint`;

	global string $br3_globalname;
	$br3_globalname = `textField -q -text br3_armRig_globalName`;
	print $br3_globalname;

	global int $br3_fk;
	global int $br3_ik;
	global int $br3_scaling;
	global int $br3_utwist;
	global int $br3_ltwist;
	$br3_fk = `checkBox -q -v br3_createArm_FK`;
	$br3_ik = `checkBox -q -v br3_createArm_IK`;
	$br3_scaling = `checkBox -q -v br3_createArm_scaling`;
	$br3_utwist = `intSliderGrp -q -v br3_armRig_upperTwistJoint`;
	$br3_ltwist = `intSliderGrp -q -v br3_armRig_lowerTwistJoint`;

	createArmRig($startjoint,$endjoint);
}


proc string[] IKleg(string $hip, string $knee, string $ankle, string $ball, string $toe, string $heel)
{
	global float $br3_size;
	global string $br3_globalname;
	
	//ikHandles
	select ($hip + ".rotatePivot") ($ankle + ".rotatePivot");
	string $ikankle[] = `ikHandle -n ("ik_" + $ankle)`;
	select ($ankle  + ".rotatePivot") ($ball + ".rotatePivot");
	string $ikball[] = `ikHandle -n ("ik_" + $ball)`;
	select ($ball + ".rotatePivot") ($toe + ".rotatePivot");
	string $iktoe[] = `ikHandle -n ("ik_" + $toe)`;
	
	//groups
	string $groupheel = `group -em -n ("group_" + $heel)`;
	palign ($heel, $groupheel);
	parent $ikankle[0] $ikball[0] $iktoe[0] $groupheel;
	string $grouptoe = `group -em -n ("group_" + $toe)`;
	parent $grouptoe $groupheel;
	palign($toe, $grouptoe);	
	parent $ikankle[0] $ikball[0] $iktoe[0] $grouptoe;
	string $groupballa = `group -em -n ("group_" + $ball + "_a")`;
	palign($ball, $groupballa);
	parent $ikankle[0] $groupballa;
	parent $groupballa $grouptoe;
	string $groupballb = `group -em -n ("group_" + $ball + "_b")`;
	palign($ball, $groupballb);
	parent $iktoe[0] $groupballb;
	parent $groupballb $grouptoe;
	
	//ctrolls
	string $heelctroll = ("ctr_" + $heel);
	makectroll($heelctroll, "cube",3,3,3);
	palign($heel,$heelctroll);
	makeIdentity -a 1 -t 1 $heelctroll;

	parent $groupheel $heelctroll;
	string $toectroll = ("ctr_" + $toe);
	makectroll($toectroll,"square",3,3,3);
	setAttr ($toectroll + ".rx") 90;
	palign($toe,$toectroll);
	
	
	parent $toectroll $heelctroll;
	parent $grouptoe $toectroll;
	string $rollctroll = ("ctr_" + $heel + "_roll");
	makectroll($rollctroll, "cylinder",9,3,3);
	palign($heel,$rollctroll);
	parent $rollctroll $heelctroll;
	makeIdentity -a 1 -t 1 $rollctroll;
	parent $toectroll $groupheel;
	makeIdentity -a 1 -t 1 $toectroll;
	string $params[] = {"tx", "ty", "tz"};
	for ($param in $params)
		setAttr -lock true -keyable false ($rollctroll + "." + $param);
	
// footroll
	string $clampnode = `shadingNode -asUtility clamp -n ($br3_globalname + "_footRollClamp01")`;
	connectAttr -force ($rollctroll + ".rotateX") ($clampnode + ".inputR");
	connectAttr -force ($clampnode + ".outputR") ($groupballa + ".rotateX");
	setAttr ($clampnode + ".maxR") 90;
	string $clampnode = `shadingNode -asUtility clamp -n ($br3_globalname + "_footRollClamp02")`;
	connectAttr -force ($rollctroll + ".rotateX") ($clampnode + ".inputR");
	connectAttr -force ($clampnode + ".outputR") ($groupheel + ".rotateX");
	setAttr ($clampnode + ".minR") -90;

// ballctroll
	string $ballctroll = ("ctr_" + $ball);
	makectroll($ballctroll, "square", 3,3,3);
	setAttr ($ballctroll + ".rx") 90;
	palign($ball, $ballctroll);
	parent $ballctroll $toectroll;
	parent $iktoe[0] $ballctroll;


//polevector
	string $polevectorname = ("ctr_" + $knee);
	makectroll($polevectorname,"sphere",3,3,3);
	select $hip $ankle $polevectorname;
	string $constrs[] = `pointConstraint`;
	delete $constrs;
	string $kinder[] = `listRelatives -c -typ joint $hip`;
	select $kinder[0] $polevectorname;
	string $constrs[] = `aimConstraint`;
	delete $constrs;
	setAttr ($polevectorname + ".tz") (`getAttr ($polevectorname + ".tz")` + $br3_size * 30); 
	makeIdentity -a 1 -t 1 -r 1 $polevectorname;
	select $polevectorname $ikankle[0];
	poleVectorConstraint;
	
	global int $br3_scaling;
	if ($br3_scaling)
		IKScaling($hip,$heelctroll);
		
	string $blendgroups[] = `globalMove $heelctroll`;
	string $eltern[] = `listRelatives -p $hip`;
	parent $blendgroups[0] $eltern[0];
	setAttr ($heelctroll + ".global") 10;
	
	hideObjs{$ikankle[0], $ikball[0], $ikankle[0], $ikball[0], $iktoe[0]};
	return {$heelctroll, $rollctroll, $toectroll};
}




proc createLegRig(string $hip, string $knee, string $ankle, string $ball, string $toe, string $heel)
{
	global int $br3_ik;
	global int $br3_fk;
	global int $br3_scaling;
	global float $br3_size;
	global string $br3_globalname;

	$br3_size = float(`getDistance $hip $ankle`) / 30;

	if (($br3_ik) && (!$br3_fk))
	{
		IKleg($hip, $knee, $ankle, $ball, $toe, $heel);
	}

	if (($br3_fk) && (!$br3_ik))
	{
		select $hip;
		br3_orientControll(1);
		select $knee $ankle $ball;
		br3_orientControll(0);
	}
	
	if (($br3_ik) && ($br3_fk))
	{
		string $dupls[] = `duplicate -rc $hip`;
		string $IKhip = `rename $dupls[0] ("IK_" + $hip)`;
		string $IKknee = `rename $dupls[1] ("IK_" + $knee)`;
		string $IKankle = `rename $dupls[2] ("IK_" + $ankle)`;
		string $IKball = `rename $dupls[3] ("IK_" + $ball)`;
		string $IKtoe = `rename $dupls[4] ("IK_" + $toe)`;

		string $dupls[] = `duplicate -rc $hip`;
		string $FKhip = `rename $dupls[0] ("FK_" + $hip)`;
		string $FKknee = `rename $dupls[1] ("FK_" + $knee)`;
		string $FKankle = `rename $dupls[2] ("FK_" + $ankle)`;
		string $FKball = `rename $dupls[3] ("FK_" + $ball)`;
		string $FKtoe = `rename $dupls[4] ("FK_" + $toe)`;

		select $FKhip;
		string $hipFKctr[] = `br3_orientControll(1)`;
		select $FKknee $FKankle $FKball;
		string $otherFKctr[] = `br3_orientControll(0)`;

		string $ikcontrolls[] = `IKleg $IKhip $IKknee $IKankle $IKball $IKtoe $heel`;

		//settings
		$settings = ("settings_" + $br3_globalname);
		makectroll($settings, "kreuz", 3,3,3);
		palign($knee, $settings);
		setAttr ($settings + ".tx") (`getAttr($settings + ".tx")` + `getAttr($knee + ".tx")`);
		addparameter($settings, "IK_blend","float");
		setAttr ($settings + ".IK_blend") 10;

		blendJoints($IKhip, $FKhip, $hip, ($settings + ".IK_blend"));
		blendJoints($IKknee, $FKknee, $knee, ($settings + ".IK_blend"));
		blendJoints($IKankle, $FKankle, $ankle, ($settings + ".IK_blend"));
		blendJoints($IKball, $FKball, $ball, ($settings + ".IK_blend"));
		
			// hide chains
		hideObjs{$IKhip,$FKhip};
		string $eltern[] = `listRelatives -p $hipFKctr[0]`;
		//antiParent($eltern[0]);
		for ($ctr in $otherFKctr)
		{
			string $eltern[] = `listRelatives -p $ctr`;
			antiParent $eltern[0];
		}
		global int $br3_utwist;
		inbetweenjoints($hip, $knee, $br3_utwist, 0);
		
		addAttr -ln "vis_FK" -k 1 -at "enum" -en "off:on:" -dv 0 ("settings_" + $br3_globalname) ;
		addAttr -ln "vis_IK" -k 1 -at "enum" -en "off:on:" -dv 1 ("settings_" + $br3_globalname) ;
		for ($ctr in $otherFKctr)
			connectAttr ("settings_" + $br3_globalname + ".vis_FK") ($ctr + ".v");
		connectAttr ("settings_" + $br3_globalname + ".vis_FK") ($hipFKctr[0] + ".v");
		
		for ($ctr in $ikcontrolls)
			connectAttr ("settings_" + $br3_globalname + ".vis_IK") ($ctr + ".v");
	}
}


global proc br3_createLegRig_Button()
{
	global int $br3_ik;
	global int $br3_fk;
	global int $br3_scaling;
	global float $br3_size;
	global string $br3_globalname;
	$br3_globalname = `textField -q -text br3_legRig_globalName`;
	$br3_fk = `checkBox -q -v br3_createLeg_FK`;
	$br3_ik = `checkBox -q -v br3_createLeg_IK`;
	$br3_scaling = `checkBox -q -v br3_createLeg_scaling`;
	
	string $hip = `textFieldButtonGrp -q -text br3_legRig_hipjoint`;
	string $knee = `textField -q -text br3_knee`;
	string $ankle = `textField -q -text br3_ankle`;
	string $ball = `textField -q -text br3_ball`;
	string $toe = `textField -q -text br3_toe`;
	string $heel = `textFieldButtonGrp -q -text br3_legRig_heelLocator`;

	createLegRig($hip, $knee, $ankle, $ball, $toe, $heel);
}


global proc br3_inversefootriglookforjoints()
{
	string $hip = `textFieldButtonGrp -q -text br3_legRig_hipjoint`;
	string $kinder[] = `listRelatives -c -typ joint $hip`;
	string $knee = $kinder[0];
	string $kinder[] = `listRelatives -c -typ joint $knee`;	
	string $ankle = $kinder[0];
	string $kinder[] = `listRelatives -c -typ joint $ankle`;
	string $ball = $kinder[0];
	string $kinder[] = `listRelatives -c -typ joint $ball`;
	string $toe = $kinder[0];
	
	textField -e -text $knee br3_knee;
	textField -e -text $ankle br3_ankle;
	textField -e -text $ball br3_ball;
	textField -e -text $toe br3_toe;
}


proc orientJoints(string $joint, string $aim, string $vector)
{
	string $kinder[] = `listRelatives -c $joint`;
	parent -w $kinder;
	if ($aim == "child")
		$aim = $kinder[0];
	select $aim $joint;
	string $constrs[];
	if ($vector != "world") 
		$constrs = `aimConstraint -offset 0 0 0 -weight 1 -aimVector 1 0 0 -upVector 0 1 0 -worldUpType "object" -worldUpObject $vector`;
	else
		$constrs = `aimConstraint -offset 0 0 0 -weight 1 -aimVector 1 0 0 -upVector 0 1 0 -worldUpType "vector" -worldUpVector 0 1 0`;
	delete $constrs;
	makeIdentity -apply true -t 0 -r 1 -s 0 -n 0 $joint;	
	parent $kinder $joint;
}


global proc br3_createBipedRig()
{
	waitCursor -st 1;

	global int $br3_fk;
	global int $br3_ik;
	global int $br3_scaling;
	global int $br3_biped;
	
	$br3_biped = 1;

// create Joints
	rebuildJoints("ROOT");
	parent -w L_hip L_shoulder;

	string $fingerjoints[] = `ls -sn "fingers_*"`;
	for ($i = 0;$i<size($fingerjoints);$i++)
	{
		setAttr ($fingerjoints[$i] + ".rotateOrder") 5;
		string $vector = ("fo_" + $fingerjoints[$i]);
		$vector = `startString $vector (size($vector) - 1)`;
		string $kinder[] = `listRelatives -c -typ joint $fingerjoints[$i]`;
		if (size($kinder))
			orientJoints($fingerjoints[$i],$kinder[0],$vector);
	}
	orientJoints("ROOT", "back_01","back_upvector");
	orientJoints("back_01", "back_02","back_upvector");
	orientJoints("back_02", "back_03","back_upvector");
	orientJoints("back_03", "neck_01","back_upvector");
	orientJoints("neck_01", "neck_02","back_upvector");
	
	orientJoints("L_upperarm", "child","back_upvector");
	orientJoints("L_upperarm", "child","back_upvector");
	orientJoints("L_elbow", "child","back_upvector");
	orientJoints("L_wrist", "fingers_L_middlefinger0","back_upvector");
	orientJoints("L_wrist2", "fingers_L_middlefinger0","back_upvector");
	
	mirrorJoint -mirrorYZ -mirrorBehavior -searchReplace "L_" "R_" "L_hip";
	mirrorJoint -mirrorYZ -mirrorBehavior -searchReplace "L_" "R_" "L_shoulder";
	parent L_hip R_hip ROOT;
	parent L_shoulder R_shoulder back_03;
	mirrorLocs{"L_heel"};

// Arms
	$br3_fk = `checkBox -q -v br3_bipedArm_FK`;
	$br3_ik = `checkBox -q -v br3_bipedArm_IK`;
	$br3_scaling = `checkBox -q -v br3_bipedArm_scaling`;
	global int $br3_utwist;								
	global int $br3_ltwist;	
	$br3_utwist = `intSliderGrp -q -v br3_armRig_biped_upperTwistJoint`;								
	$br3_ltwist = `intSliderGrp -q -v br3_armRig_biped_lowerTwistJoint`;	
	
	//left arm
	string $startjoint = "L_upperarm";
	string $endjoint = "L_wrist";
	global string $br3_globalname;
	$br3_globalname = "L_arm";
	createArmRig($startjoint,$endjoint);	
	//right arm
	string $startjoint = "R_upperarm";
	string $endjoint = "R_wrist";
	global string $br3_globalname;
	$br3_globalname = "R_arm";

	createArmRig($startjoint,$endjoint);	

// Fingers
	global float $br3_size;
	string $fingerjoints[] = `ls -et joint -sn "fingers_*"`;
	$br3_size = float(`getDistance $fingerjoints[0] $fingerjoints[1]`) / 10;
	select $fingerjoints;
	for ($fingerjoint in $fingerjoints)
	{
		string $kinder[] = `listRelatives -c -typ joint $fingerjoint`;
		if (size($kinder))
		{
			select $fingerjoint;
			br3_orientControll(0);
		}
	}

// Legs
	$br3_fk = `checkBox -q -v br3_bipedLeg_FK`;
	$br3_ik = `checkBox -q -v br3_bipedLeg_IK`;
	$br3_scaling = `checkBox -q -v br3_bipedLeg_scaling`;
	$br3_utwist = `intSliderGrp -q -v br3_legRig_biped_upperTwistJoint`;								

	//left leg
	$br3_globalname = "L_leg";
	createLegRig("L_hip", "L_knee", "L_ankle", "L_ball", "L_toe", "L_heel");
	//right leg
	$br3_globalname = "R_leg";
	createLegRig("R_hip", "R_knee", "R_ankle", "R_ball", "R_toe", "R_heel");

// Back
	$br3_fk = `checkBox -q -v br3_bipedBack_FK`;
	$br3_ik = `checkBox -q -v br3_bipedBack_IK`;
	$br3_scaling = `checkBox -q -v br3_bipedBack_scaling`;
	$br3_globalname = "Back";
	createBackRig("ROOT", "back_03");
	
// Neck / Head
	global float $br3_size;
	$br3_size = float(`getDistance "neck_01" "neck_02"`) / 10;
	$br3_scaling = `checkBox -q -v br3_bipedHead_scaling`;
	select neck_01;
	string $fk_contrs[] = `br3_orientControll 0`;
	setAttr -lock true ($fk_contrs[0] + ".rx");
	select neck_02;
	br3_orientControll(1);

	$br3_utwist = `intSliderGrp -q -v br3_neckRig_biped_TwistJoint`;
	inbetweenjoints("neck_01", "neck_02", $br3_utwist, 1);
	
// Fixing
	if (`objExists "ROOT_addjoint"`)
	{
		if (`objExists "ctr_FK_R_hip_localRotateGroup"`)
			parent ctr_FK_R_hip_localRotateGroup ROOT_addjoint;
		if (`objExists "ctr_FK_L_hip_localRotateGroup"`)
			parent ctr_FK_L_hip_localRotateGroup ROOT_addjoint;
		if (`objExists "ctr_R_heel_localTranslateGroup"`)
			parent ctr_R_heel_localTranslateGroup ROOT_addjoint;
		if (`objExists "ctr_L_heel_localTranslateGroup"`)
			parent ctr_L_heel_localTranslateGroup ROOT_addjoint;
	}
	waitCursor -st 0;
	
	
// Globaltransform

	$br3_size = float(`getDistance "L_knee" "neck_02"`) / 10;
	makectroll("bittnerRig3_Transform","square", 10, 10, 10);

	string $names[] = {"settings_*", "*_globalTranslateGroup", "*_globalTranslateGroup", "*_polevector", "ctr_IK_*",
		 "*_blendTranslateGroup", "*_globalRotateGroup", "*_blendRotateGroup", "antiParentGroup*", "br3_*"};
	for ($name in $names)
	{
		string $objs[] = `ls -et transform -sn $name`;
		string $addobjs[] = `ls -et ikHandle -sn $name`;
		for ($addobj in $addobjs)
			$objs[size($objs)] = $addobj;
		for ($obj in $objs)
		{
			string $eltern[] = `listRelatives -p $obj`;
			if (!size($eltern))
				parent $obj "bittnerRig3_Transform";
		}
	}
	parent "ctr_Back_root" "bittnerRig3_Transform";
	// Measure Tools
	string $objtypes[] = {"distanceDimShape", "curveInfo"};
	for ($objtype in $objtypes)
	{
		string $disShapes[] = `ls -et $objtype`;
		for ($dis in $disShapes)
		{
			string $conns[] = `listConnections -s 0 -p 1 $dis`;
			string $param;
			for ($conn in $conns)
			{
				if ($objtype == "distanceDimShape")
					$param = "distance";
				else
					$param = "arcLength";
				disconnectAttr ($dis + "." + $param) $conn;
				string $multipl = `shadingNode -asUtility multiplyDivide -n "rev_scaler"`;
				connectAttr ($dis + "." + $param) ($multipl + ".input1X");
				connectAttr ("bittnerRig3_Transform.sx") ($multipl + ".input2X");
				setAttr ($multipl + ".operation") 2;
				connectAttr ($multipl + ".outputX") $conn;
			}
		}
	}
	
	string $splineCurves[] = `ls -et transform -sn "br3_splineHandleCurve*"`;
	for ($curve in $splineCurves)
		setAttr ($curve + ".inheritsTransform") 0;

	delete bittnerRig3_guide R_heel;
}


proc string[] createBackLegIK(string $hip, string $knee, string $ankle, string $heel, string $toe)
{
	string $mainIkCol[] = `makeIKchain $hip $heel`;
	select ($heel + ".rotatePivot") ($toe + ".rotatePivot");
	string $toeIkCol[] = `ikHandle`;
	parent $toeIkCol[0] $mainIkCol[0];
	hideObjs{$toeIkCol[0]};

	string $groups[] = `globalMove $mainIkCol[0]`;
	string $eltern[] = `listRelatives -p $hip`;
	parent $groups[0] $eltern[0];
	setAttr ($mainIkCol[0] + ".global") 10;

	return{$mainIkCol[0], $mainIkCol[1]};
}

proc createBackLeg(string $hip, string $knee, string $ankle, string $heel, string $toe)
{
	global float $br3_size;
	global int $br3_fk;
	global int $br3_ik;
	global string $br3_globalname;
	
	$br3_size = float(`getDistance $hip $ankle`) / 30;
	if (($br3_fk) && (!$br3_ik))
	{
		select $knee $ankle $heel;
		br3_orientControll(0);
		select $hip;
		br3_orientControll(1);
	}
	if ((!$br3_fk) && ($br3_ik))
	{
		createBackLegIK($hip, $knee, $ankle, $heel, $toe);
	}
	if (($br3_fk) && ($br3_ik))
	{
	//settings
		$settings = ("settings_" + $br3_globalname);
		makectroll($settings, "kreuz", 3,3,3);
		palign($knee, $settings);
		setAttr ($settings + ".tx") (`getAttr($settings + ".tx")` + `getAttr($knee + ".tx")`);
		addparameter($settings, "IK_blend","float");
		setAttr ($settings + ".IK_blend") 10;

		string $legjoints[] = {$hip, $knee, $ankle, $heel, $toe};
		string $FKleg[];
		string $IKleg[];
		
		string $dupls[] = `duplicate -rc $legjoints[0]`;	
		for ($i = 0;$i < size($legjoints);$i++)
			$FKleg[$i] = `rename $dupls[$i] ("FK" + $legjoints[$i])`;

		string $dupls[] = `duplicate -rc $legjoints[0]`;		
		for ($i = 0;$i < size($legjoints);$i++)
			$IKleg[$i] = `rename $dupls[$i] ("IK" + $legjoints[$i])`;	
		
		string $ikcontrs[] = `createBackLegIK $IKleg[0] $IKleg[1] $IKleg[2] $IKleg[3] $IKleg[4]`;
		
		select $FKleg[1] $FKleg[2] $FKleg[3];
		string $fk_contrs[] = `br3_orientControll 0`;
		select $FKleg[0];
		string $hipcontr[] = `br3_orientControll 1`;
		
		for ($i = 0;$i<size($legjoints);$i++)
			blendJoints($IKleg[$i], $FKleg[$i], $legjoints[$i], ("settings_" + $br3_globalname + ".IK_blend"));
		setAttr ("settings_" + $br3_globalname + ".IK_blend") 10;
			
		for ($contr in $fk_contrs)
		{
			string $eltern[] = `listRelatives -p -typ transform $contr`;
			antiParent($eltern[0]);
		}
		hideObjs{$IKleg[0], $FKleg[0]};

		addAttr -ln "vis_FK" -k 1 -at "enum" -en "off:on:" -dv 0 ("settings_" + $br3_globalname);
		addAttr -ln "vis_IK" -k 1 -at "enum" -en "off:on:" -dv 1 ("settings_" + $br3_globalname);
		for ($ctr in $fk_contrs)
			connectAttr ("settings_" + $br3_globalname + ".vis_FK") ($ctr + ".v");
		connectAttr ("settings_" + $br3_globalname + ".vis_FK") ($hipcontr[0] + ".v");
		for ($ctr in $ikcontrs)
			connectAttr ("settings_" + $br3_globalname + ".vis_IK") ($ctr + ".v");
	}
}



proc string[] createFrontLegIK(string $hip, string $knee, string $ankle, string $heel, string $toe)
{
	global string $br3_globalname;
	
	string $handleCol[] = `makeIKchain $hip $ankle`;
	string $kinder[] = `listRelatives -c -typ pointConstraint $handleCol[2]`;
	delete $kinder[0];
	string $effectors[] = `listConnections -t ikEffector $handleCol[2]`;
	float $heelpos[2] = `xform -q -ws -t $heel`;
	print $heelpos;
	print $handleCol[2];
	move -ws -a -rpr $heelpos[0] $heelpos[1] $heelpos[2] ($effectors[0] + ".rotatePivot") ($effectors[0] + ".scalePivot");
	
	string $kinder[] = `listRelatives -c -typ transform $handleCol[0]`;
	parent -w $kinder;
	move -ws -a -rpr $heelpos[0] $heelpos[1] $heelpos[2] $handleCol[0];
	parent $kinder $handleCol[0];
	select $handleCol[0] $handleCol[2];
	pointConstraint;

	string $clampnode = `shadingNode -asUtility clamp -n ($br3_globalname + "_" + $ankle + "_makeOnlyPositive")`;
	connectAttr -force ($handleCol[0] + ".rotateX") ($clampnode + ".inputR");
	setAttr ($clampnode + ".maxR") 1000;
	connectAttr -force ($clampnode + ".outputR") ($ankle + ".rotateZ");

	string $roll = ($br3_globalname + "_roll");
	makectroll($roll, "cylinder", 5, 3, 3);
	parent $roll $handleCol[0];
	select $heel $roll; pointConstraint;
	select $roll $heel; orientConstraint -mo;
	
	string $groups[] = `globalMove $handleCol[0]`;
	string $eltern[] = `listRelatives -p $hip`;
	parent $groups[0] $eltern[0];
	setAttr ($handleCol[0] + ".global") 10;
	
	return {$handleCol[0], $handleCol[1], $roll};
}


proc createFrontLeg(string $hip, string $knee, string $ankle, string $heel, string $toe)
{
	global float $br3_size;
	global int $br3_fk;
	global int $br3_ik;
	global string $br3_globalname;
	
	$br3_size = float(`getDistance $hip $ankle`) / 30;
	if (($br3_fk) && (!$br3_ik))
	{
		select $knee $ankle $heel;
		br3_orientControll(0);
		select $hip;
		br3_orientControll(1);
	}
	if ((!$br3_fk) && ($br3_ik))
	{
		createFrontLegIK($hip, $knee, $ankle, $heel, $toe);
	}
	if (($br3_fk) && ($br3_ik))
	{
	//settings
		$settings = ("settings_" + $br3_globalname);
		makectroll($settings, "kreuz", 3,3,3);
		palign($knee, $settings);
		setAttr ($settings + ".tx") (`getAttr($settings + ".tx")` + `getAttr($knee + ".tx")`*0.5);
		addparameter($settings, "IK_blend","float");
		setAttr ($settings + ".IK_blend") 10;

		string $legjoints[] = {$hip, $knee, $ankle, $heel, $toe};
		string $FKleg[];
		string $IKleg[];
		
		string $dupls[] = `duplicate -rc $legjoints[0]`;	
		for ($i = 0;$i < size($legjoints);$i++)
			$FKleg[$i] = `rename $dupls[$i] ("FK" + $legjoints[$i])`;

		string $dupls[] = `duplicate -rc $legjoints[0]`;		
		for ($i = 0;$i < size($legjoints);$i++)
			$IKleg[$i] = `rename $dupls[$i] ("IK" + $legjoints[$i])`;	
		
		string $ik_contrs[] = `createFrontLegIK $IKleg[0] $IKleg[1] $IKleg[2] $IKleg[3] $IKleg[4]`;
		
		select $FKleg[1] $FKleg[2] $FKleg[3];
		string $fk_contrs[] = `br3_orientControll 0`;
		select $FKleg[0];
		string $hipcontr[] = `br3_orientControll 1`;
		
		for ($i = 0;$i<size($legjoints);$i++)
			blendJoints($IKleg[$i], $FKleg[$i], $legjoints[$i], ("settings_" + $br3_globalname + ".IK_blend"));
		setAttr ("settings_" + $br3_globalname + ".IK_blend") 10;
			
		for ($contr in $fk_contrs)
		{
			string $eltern[] = `listRelatives -p -typ transform $contr`;
			antiParent($eltern[0]);
		}
		hideObjs{$IKleg[0], $FKleg[0]};
		
		addAttr -ln "vis_FK" -k 1 -at "enum" -en "off:on:" -dv 0 ("settings_" + $br3_globalname);
		addAttr -ln "vis_IK" -k 1 -at "enum" -en "off:on:" -dv 1 ("settings_" + $br3_globalname);
		for ($ctr in $fk_contrs)
			connectAttr ("settings_" + $br3_globalname + ".vis_FK") ($ctr + ".v");
		connectAttr ("settings_" + $br3_globalname + ".vis_FK") ($hipcontr[0] + ".v");
		for ($ctr in $ik_contrs)
			connectAttr ("settings_" + $br3_globalname + ".vis_IK") ($ctr + ".v");
	}	
}


global proc br3_createQuadrupedRig()
{
	waitCursor -st 1;

	global int $br3_biped;
	global int $br3_fk;
	global int $br3_ik;
	global int $br3_scaling;
	global string $br3_globalname;
	global float $br3_size;
	$br3_biped = 0;
	
// create Joints
	rebuildJoints("ROOT");
	parent -w L_f_shoulder L_b_hip;
	mirrorJoint -mirrorYZ -mirrorBehavior -searchReplace "L_" "R_" "L_f_shoulder";
	mirrorJoint -mirrorYZ -mirrorBehavior -searchReplace "L_" "R_" "L_b_hip";
	parent L_f_shoulder R_f_shoulder neck_01;
	parent L_b_hip R_b_hip ROOT;
	
// Front Legs
	$br3_fk = `checkBox -q -v br3_quadrupedArm_FK`;
	$br3_ik = `checkBox -q -v br3_quadrupedArm_IK`;
	$br3_scaling = `checkBox -q -v br3_quadrupedArm_scaling`;
	global int $br3_utwist;								
	global int $br3_ltwist;	
	//$br3_utwist = `intSliderGrp -q -v br3_armRig_quadruped_upperTwistJoint`;								
	

   // frontlegs LEFT
	$br3_globalname = "L_f_leg";
	select L_f_shoulder;
	//br3_orientControll(1);
	string $hip = "L_f_hip";
	string $knee = "L_f_knee";
	string $ankle = "L_f_ankle";
	string $heel = "L_f_heel";
	string $toe = "L_f_toe";
	createFrontLeg("L_f_hip", "L_f_knee", "L_f_ankle", "L_f_heel", "L_f_toe");
	select L_f_shoulder;
	br3_orientControll(1);

	
  // frontlegs RIGHT
  	$br3_globalname = "R_f_leg";
  	string $hip = "R_f_hip";
  	string $knee = "R_f_knee";
  	string $ankle = "R_f_ankle";
  	string $heel = "R_f_heel";
  	string $toe = "R_f_toe";
	createFrontLeg("R_f_hip", "R_f_knee", "R_f_ankle", "R_f_heel", "R_f_toe");
	select R_f_shoulder;
	br3_orientControll(1);
	

// Back Legs
  // backlegs LEFT
  	$br3_fk = `checkBox -q -v br3_quadrupedLeg_FK`;
	$br3_ik = `checkBox -q -v br3_quadrupedLeg_IK`;
  	$br3_globalname = "L_b_leg";
  	string $hip = "L_b_hip";
  	string $knee = "L_b_knee";
  	string $ankle = "L_b_ankle";
  	string $heel = "L_b_heel";
  	string $toe = "L_b_toe";
  	createBackLeg("L_b_hip", "L_b_knee", "L_b_ankle", "L_b_heel", "L_b_toe");
  	
 // backlegs RIGHT
  	$br3_globalname = "R_b_leg";
  	string $hip = "R_b_hip";
  	string $knee = "R_b_knee";
  	string $ankle = "R_b_ankle";
  	string $heel = "R_b_heel";
  	string $toe = "R_b_toe";
  	createBackLeg("R_b_hip", "R_b_knee", "R_b_ankle", "R_b_heel", "R_b_toe");

// Back
	$br3_fk = `checkBox -q -v br3_quadrupedBack_FK`;
	$br3_ik = `checkBox -q -v br3_quadrupedBack_IK`;
	$br3_scaling = `checkBox -q -v br3_quadrupedBack_scaling`;
	$br3_globalname = "Back";
	createBackRig("ROOT", "neck_01");
	
// Head
	$br3_size = `getDistance "neck_01" "head_01"` / 20;
	select neck_02;
	string $fkcontrs[] = `br3_orientControll 0`;
	setAttr -lock true ($fkcontrs[0] + ".rx");
	select head_01;
	br3_orientControll(1);
	$br3_utwist = `intSliderGrp -q -v br3_neckRig_quadruped_TwistJoint`;
	inbetweenjoints("neck_02", "head_01", $br3_utwist, 1);
	
	
	
// Tail
	string $tailjoints[] = `ls -et joint -sn "tail_*"`;
	$br3_size = float(`getDistance $tailjoints[0] $tailjoints[1]`) / 10;
	select $tailjoints;
	for ($tailjoint in $tailjoints)
	{
		string $kinder[] = `listRelatives -c -typ joint $tailjoint`;
		if (size($kinder))
		{
			select $tailjoint;
			br3_orientControll(0);
		}
	}
	
// Globaltransform
	$br3_size = float(`getDistance "ROOT" "neck_02"`) / 10;
	makectroll("bittnerRig3_Transform","square", 10, 10, 10);

	string $names[] = {"settings_*", "*_globalTranslateGroup", "*_globalTranslateGroup", "*_polevector", "ctr_IK_*",
		 "*_blendTranslateGroup", "*_globalRotateGroup", "*_blendRotateGroup", "antiParentGroup*", "br3_*"};
	for ($name in $names)
	{
		string $objs[] = `ls -et transform -sn $name`;
		string $addobjs[] = `ls -et ikHandle -sn $name`;
		for ($addobj in $addobjs)
			$objs[size($objs)] = $addobj;
		for ($obj in $objs)
		{
			string $eltern[] = `listRelatives -p $obj`;
			if (!size($eltern))
				parent $obj "bittnerRig3_Transform";
		}
	}
	parent "ctr_Back_root" "bittnerRig3_Transform";
	// Measure Tools
	string $objtypes[] = {"distanceDimShape", "curveInfo"};
	for ($objtype in $objtypes)
	{
		string $disShapes[] = `ls -et $objtype`;
		for ($dis in $disShapes)
		{
			string $conns[] = `listConnections -s 0 -p 1 $dis`;
			string $param;
			for ($conn in $conns)
			{
				if ($objtype == "distanceDimShape")
					$param = "distance";
				else
					$param = "arcLength";
				disconnectAttr ($dis + "." + $param) $conn;
				string $multipl = `shadingNode -asUtility multiplyDivide -n "rev_scaler"`;
				connectAttr ($dis + "." + $param) ($multipl + ".input1X");
				connectAttr ("bittnerRig3_Transform.sx") ($multipl + ".input2X");
				setAttr ($multipl + ".operation") 2;
				connectAttr ($multipl + ".outputX") $conn;
			}
		}
	}
	
	string $splineCurves[] = `ls -et transform -sn "br3_splineHandleCurve*"`;
	for ($curve in $splineCurves)
	setAttr ($curve + ".inheritsTransform") 0;
	
	if (`objExists "ROOT_addjoint"`)
	{			
		if (`objExists "ctr_FKL_b_hip_localRotateGroup"`)
			parent ctr_FKL_b_hip_localRotateGroup ROOT_addjoint;
		if (`objExists "FKL_b_hip_rotateGroup"`)
			parent FKL_b_hip_rotateGroup ROOT_addjoint;
		if (`objExists "ctrIK_L_b_leg_localTranslateGroup"`)
			parent ctrIK_L_b_leg_localTranslateGroup ROOT_addjoint;
		if (`objExists "ctrIK_R_b_leg_localTranslateGroup"`)
			parent ctrIK_R_b_leg_localTranslateGroup ROOT_addjoint;
		if (`objExists "FKR_b_hip_rotateGroup"`)
			parent FKR_b_hip_rotateGroup ROOT_addjoint;
		if (`objExists "ctr_FKR_b_hip_localRotateGroup"`)
			parent ctr_FKR_b_hip_localRotateGroup ROOT_addjoint;
	}	

	delete bittnerRig3_guide ;

	waitCursor -st 0;
}



global proc bittnerRig_3()
{

	global int $br3_biped;
	$br3_biped = 1;
	if (`window -exists br3_window`)
		deleteUI br3_window;

	window -widthHeight 200 150 -t bittnerRig_3 br3_window;
		string $form = `formLayout`;

		string $bottomtask = `columnLayout -co "left" 30 -rs 5`;
			checkBox -l "show Building-Process" -v 0 br3_cb_buildingprocess;
		setParent..;

		string $tabs = `tabLayout -innerMarginWidth 5 -innerMarginHeight 5`;

		formLayout -edit
			-attachForm $tabs "top"    0
			-attachForm $tabs "left"   0
			-attachControl $tabs "bottom" 0 $bottomtask
			-attachForm $tabs "right"  0

			-attachNone $bottomtask "top"
			-attachForm $bottomtask "right" 0
			-attachForm $bottomtask "left" 0
			-attachForm $bottomtask "bottom" 0
			$form;

			string $tab_biped = `scrollLayout`;
				columnLayout;
					frameLayout -collapsable true -width 500 -label "Create Guide" ;
						columnLayout -co "both" 10 -rs 10;
							button 	-l "create Biped Guide"	-w 150 -h 30 -c "br3_createBipedGuide()";
						setParent..;
					setParent..;
					frameLayout -collapsable true -width 500 -label "Adjust" ;
						columnLayout -co "both" 10 -rs 10;
							frameLayout -label "Arms" -labelAlign "center" -borderStyle "etchedIn" -width 470;
								columnLayout -co "both" 20;
									checkBox -l "Forward Kinematics" -v 1 br3_bipedArm_FK;
									checkBox -l "Inverse Kinematics" -v 1 br3_bipedArm_IK;
									checkBox -l "Squash and Stretch" -v 1 br3_bipedArm_scaling;
									intSliderGrp -label "upperArm twistJoints" -v 2 -max 10 -f 1 br3_armRig_biped_upperTwistJoint;
									intSliderGrp -label "lowerArm twistJoints" -v 3 -max 10 -f 1 br3_armRig_biped_lowerTwistJoint;								
								setParent..;
							setParent..;
							frameLayout -label "Legs" -labelAlign "center" -borderStyle "etchedIn" -width 470;
								columnLayout -co "both" 20;
									checkBox -l "Forward Kinematics" -v 1 br3_bipedLeg_FK;
									checkBox -l "Inverse Kinematics" -v 1 br3_bipedLeg_IK;
									checkBox -l "Squash and Stretch" -v 1 br3_bipedLeg_scaling;	
									intSliderGrp -label "upperLeg twistJoints" -v 3 -max 10 -f 1 br3_legRig_biped_upperTwistJoint;

								setParent..;
							setParent..;
							frameLayout -label "Back" -labelAlign "center" -borderStyle "etchedIn" -width 470;
								columnLayout -co "both" 20;
									checkBox -l "Forward Kinematics" -v 1 br3_bipedBack_FK;
									checkBox -l "Inverse Kinematics" -v 1 br3_bipedBack_IK;
									checkBox -l "Squash and Stretch" -v 1 br3_bipedBack_scaling;					
								setParent..;
							setParent..;
							frameLayout -label "Neck / Head" -labelAlign "center" -borderStyle "etchedIn" -width 470;
								columnLayout -co "both" 20;
									checkBox -l "Squash and Stretch" -v 1 br3_bipedHead_scaling;					
									intSliderGrp -label "neck twistJoints" -v 2 -max 10 -f 1 br3_neckRig_biped_TwistJoint;
								setParent..;
							setParent..;						
						setParent..;
					setParent..;
					frameLayout -collapsable true -width 500 -label "Create Rig" ;
						columnLayout -co "both" 10 -rs 10;
							button 	-l "create Rig"-w 150 -h 30 -c "br3_createBipedRig()";
						setParent..;
					setParent..;
				setParent..;			
			setParent..;

			string $tab_quadruped = `scrollLayout`;
				columnLayout;
					frameLayout -collapsable true -width 500 -label "Create Quadruped Guide" ;
						columnLayout -co "both" 10 -rs 10;
							button 	-l "create Quadruped Guide"	-w 150 -h 30 -c "br3_createQuadrupedGuide()";
						setParent..;
					setParent..;
					frameLayout -collapsable true -width 500 -label "Adjust" ;
						columnLayout -co "both" 10 -rs 10;
							frameLayout -label "Front Legs" -labelAlign "center" -borderStyle "etchedIn" -width 470;
								columnLayout -co "both" 20;
									checkBox -l "Forward Kinematics" -v 1 br3_quadrupedArm_FK;
									checkBox -l "Inverse Kinematics" -v 1 br3_quadrupedArm_IK;
									checkBox -l "Squash and Stretch" -v 1 br3_quadrupedArm_scaling;
//									intSliderGrp -label "upperArm twistJoints" -v 2 -max 10 -f 1 br3_armRig_quadruped_upperTwistJoint;
//									intSliderGrp -label "lowerArm twistJoints" -v 3 -max 10 -f 1 br3_armRig_quadruped_lowerTwistJoint;								
								setParent..;
							setParent..;
							frameLayout -label "Back Legs" -labelAlign "center" -borderStyle "etchedIn" -width 470;
								columnLayout -co "both" 20;
									checkBox -l "Forward Kinematics" -v 1 br3_quadrupedLeg_FK;
									checkBox -l "Inverse Kinematics" -v 1 br3_quadrupedLeg_IK;
									checkBox -l "Squash and Stretch" -v 1 br3_quadrupedLeg_scaling;	
//									intSliderGrp -label "upperLeg twistJoints" -v 3 -max 10 -f 1 br3_legRig_quadruped_upperTwistJoint;

								setParent..;
							setParent..;
							frameLayout -label "Back" -labelAlign "center" -borderStyle "etchedIn" -width 470;
								columnLayout -co "both" 20;
									checkBox -l "Forward Kinematics" -v 1 br3_quadrupedBack_FK;
									checkBox -l "Inverse Kinematics" -v 1 br3_quadrupedBack_IK;
									checkBox -l "Squash and Stretch" -v 1 br3_quadrupedBack_scaling;					
								setParent..;
							setParent..;
							frameLayout -label "Neck / Head" -labelAlign "center" -borderStyle "etchedIn" -width 470;
								columnLayout -co "both" 20;
									checkBox -l "Squash and Stretch" -v 1 br3_quadrupedHead_scaling;					
									intSliderGrp -label "neck twistJoints" -v 2 -max 10 -f 1 br3_neckRig_quadruped_TwistJoint;
								setParent..;
							setParent..;						
						setParent..;
					setParent..;
					frameLayout -collapsable true -width 500 -label "Create Rig" ;
						columnLayout -co "both" 10 -rs 10;
							button 	-l "create Rig"-w 150 -h 30 -c "br3_createQuadrupedRig()";
						setParent..;
					setParent..;
				setParent..;			
			setParent..;

			string $tab_extraParts = `formLayout`;
				string $rigbuilderscroll = `scrollLayout`;
					columnLayout;
						frameLayout -collapsable true -width 500 -label "Create Arm Rig" ;
							columnLayout -co "both" 10 -rs 10;
								columnLayout;
									rowColumnLayout -nc 2;
										text -l "name";
										textField br3_armRig_globalName;
									setParent..;

									textFieldButtonGrp 	-label "set shoulderJoint" 
												-text "empty" 
												-buttonLabel "selected Object" 
												-bc "br3_updateField(\"br3_armRig_startJoint\", \"joint\")"
												br3_armRig_startJoint;
									textFieldButtonGrp 	-label "set wristJoint" 
												-text "empty" 
												-buttonLabel "selected Object" 
												-bc "br3_updateField(\"br3_armRig_endJoint\", \"joint\")"
												br3_armRig_endJoint;				
									checkBox -l "Forward Kinematics" -v 1 br3_createArm_FK;
									checkBox -l "Inverse Kinematics" -v 1 br3_createArm_IK;
									checkBox -l "Squash and Stretch" -v 1 br3_createArm_scaling;
									intSliderGrp -label "upperArm twistJoints" -max 10 -f 1 br3_armRig_upperTwistJoint;
									intSliderGrp -label "lowerArm twistJoints" -max 10 -f 1 br3_armRig_lowerTwistJoint;

								setParent..;
									columnLayout;
										button 	-l "create Arm Rig"
											-w 100
											-h 30
											-c "br3_createArmRig_Button()";
								setParent..;
							setParent..;
						setParent..;

						frameLayout -collapsable true -width 500 -label "Create Leg Rig" ;
							columnLayout -co "both" 10 -rs 10;	
								columnLayout;
									rowColumnLayout -nc 2;
										text -l "name";
										textField br3_legRig_globalName;
									setParent..;							
									textFieldButtonGrp 	-label "set Hip (Joint)" 
												-text "empty" 
												-buttonLabel "selected Object" 
												-bc "br3_updateField(\"br3_legRig_hipjoint\", \"joint\")"
												br3_legRig_hipjoint;
									textFieldButtonGrp 	-label "set Heel (Locator)" 
												-text "empty" 
												-buttonLabel "selected Object" 
												-bc "br3_updateField(\"br3_legRig_heelLocator\", \"locator\")"
												br3_legRig_heelLocator;
									button -l "look for other joints" -c "br3_inversefootriglookforjoints()";
									rowColumnLayout -nc 2; text -l "knee"; textField -tx "empty" -en 0 br3_knee; setParent..;
									rowColumnLayout -nc 2; text -l "ankle"; textField -tx "empty" -en 0 br3_ankle; setParent..;
									rowColumnLayout -nc 2; text -l "ball"; textField -tx "empty" -en 0 br3_ball; setParent..;
									rowColumnLayout -nc 2; text -l "toe"; textField -tx "empty" -en 0 br3_toe; setParent..;

									checkBox -l "Forward Kinematics" -v 1 br3_createLeg_FK;
									checkBox -l "Inverse Kinematics" -v 1 br3_createLeg_IK;
									checkBox -l "Squash and Stretch" -v 1 br3_createLeg_scaling;	
									intSliderGrp -label "upperLeg twistJoints" -max 10 -f 1 br3_legRig_upperTwistJoint;

								setParent..;


								columnLayout;
									button 	-l "Create Leg Rig"
										-w 100
										-h 30
										-c "br3_createLegRig_Button()";
								setParent..;	

							setParent..;
						setParent..;

						frameLayout -collapsable true -width 500 -label "Create Back Rig" ;
							columnLayout -co "both" 10 -rs 10;
								columnLayout;
									rowColumnLayout -nc 2;
										text -l "name";
										textField br3_backRig_globalName;
									setParent..;

									textFieldButtonGrp 	-label "set first Joint" 
												-text "empty" 
												-buttonLabel "selected Object" 
												-bc "br3_updateField(\"br3_backRig_startJoint\", \"joint\")"
												br3_backRig_startJoint;
									textFieldButtonGrp 	-label "set last Joint" 
												-text "empty" 
												-buttonLabel "selected Object" 
												-bc "br3_updateField(\"br3_backRig_endJoint\", \"joint\")"
												br3_backRig_endJoint;				
									checkBox -l "Forward Kinematics" -v 1 br3_backRig_FK;
									checkBox -l "Inverse Kinematics (splineHandle)" -v 1 br3_backRig_IK;
									checkBox -l "Squash and Stretch" -v 1 br3_backRig_scaling;

								setParent..;
									columnLayout;
										button 	-l "create backRig"
											-w 100
											-h 30
											-c "br3_createbackRig_Button()";
								setParent..;
							setParent..;
						setParent..;

						frameLayout -collapsable true -width 500 -label "Create SplineHandle" ;
							columnLayout -co "both" 10 -rs 10;	
								columnLayout;
									checkBox 	-l "by Curve" 
											-v 0
											-ofc "textFieldButtonGrp -e -m 1 br3_splineRig_startJoint;textFieldButtonGrp -e -m 1 br3_splineRig_endJoint;textFieldButtonGrp -e -m 0 br3_splineRig_curve;intSliderGrp -e -m 0 br3_ikSplineByCurveAnzahlDerJoints;textField -e -m 0 br3_iksplinehandlejointname;text -e -m 0 br3_iksplinehandlejointnametextbefore;"
											-onc "textFieldButtonGrp -e -m 0 br3_splineRig_startJoint;textFieldButtonGrp -e -m 0 br3_splineRig_endJoint;textFieldButtonGrp -e -m 1 br3_splineRig_curve;intSliderGrp -e -m 1 br3_ikSplineByCurveAnzahlDerJoints;textField -e -m 1 br3_iksplinehandlejointname;text -e -m 1 br3_iksplinehandlejointnametextbefore;"
											br3_splineHandleByCurveOrNot;

									textFieldButtonGrp 	-label "set startJoint" 
												-m 1
												-text "empty" 
												-buttonLabel "selected Object" 
												-bc "br3_updateField(\"br3_splineRig_startJoint\", \"joint\")"
												br3_splineRig_startJoint;
									textFieldButtonGrp 	-label "set endJoint" 
												-m 1
												-text "empty" 
												-buttonLabel "selected Object" 
												-bc "br3_updateField(\"br3_splineRig_endJoint\", \"joint\")"
												br3_splineRig_endJoint;	
									textFieldButtonGrp 	-label "set curve" 
												-m 0
												-text "empty" 
												-buttonLabel "selected Object" 
												-bc "br3_updateField(\"br3_splineRig_curve\", \"nurbsCurve\")"
												br3_splineRig_curve;
									intSliderGrp -field true -m 0 -v 10 -max 1000 -label "and so many joints:" br3_ikSplineByCurveAnzahlDerJoints;
									rowColumnLayout -nc 2;
										text -l "name of the joints:" -m 0 br3_iksplinehandlejointnametextbefore;
										textField -tx "newName" -m 0 br3_iksplinehandlejointname;
									setParent..;

									checkBox -l "autoScale" chbx_br3_scalejointsSpline;
									checkBox -l "use Translate-Values for Scale" -v 1 chbx_br3_tanslatevaluesSpline;
									checkBox -l "all same translateX" -v 0 chbx_br3_sametranslateXSpline;
								setParent..;
								columnLayout;
									button 	-l "create ikSpline"
										-w 100
										-h 30
										-c "br3_createikSplineButton()";
								setParent..;	
							setParent..;
						setParent..;

						frameLayout -collapsable true -width 500 -label "Orient Controll" ;
							columnLayout -co "both" 10 -rs 10 ;
								columnLayout;
									button 	-l "create Local Orient Controll"
											-w 200
											-h 30
											-c "br3_orientControll(0)";	
									button 	-l "create Controll with Global-Blend"
											-w 200
											-h 30
											-c "br3_orientControll(1)";					
								setParent..;
							setParent..;
						setParent..;

						frameLayout -collapsable true -width 500 -label "Create Controll Curves" ;
							columnLayout -co "both" 10 -rs 10 ;
								columnLayout;
									button 	-l "create Circle" -w 200 -h 30 -c "br3_createControll(\"circle\")";					
									button 	-l "create Square" -w 200 -h 30 -c "br3_createControll(\"square\")";
									button 	-l "create Cube" -w 200 -h 30 -c "br3_createControll(\"cube\")";
									button 	-l "create Sphere" -w 200 -h 30 -c "br3_createControll(\"sphere\")";					
									button 	-l "create Cylinder" -w 200 -h 30 -c "br3_createControll(\"cylinder\")";					
								setParent..;
							setParent..;
						setParent..;

					setParent..;
					setParent..;
					formLayout -edit
							-attachForm     $rigbuilderscroll	"top"    2
							-attachForm     $rigbuilderscroll	"left"   2
							-attachForm	$rigbuilderscroll	"bottom" 2 
							-attachForm	$rigbuilderscroll	"right"  2 
					$tab_extraParts;



				setParent..;

				string $child3 = `columnLayout -adj 1`;
					text -label "" 	-align "right";
					text -label "bittnerRig3"			-align "center";
					text -label ""    					-align "center";
					text -label "Author:"					-align "center";
					text -label "  Thomas Bittner"				-align "center";
					text -label "  www.thomasbittner.at"			-align "center";
					text -label "  thomasbittner@hotmail.de"		-align "center";
					text -label ""						-align "center";
					text -label "copyRight September - March 2006"		-align "center"; 	
				setParent..;


			tabLayout -edit
				-tabLabel $tab_biped "Biped Rig" 
				-tabLabel $tab_quadruped "Quadruped Rig"
				-tabLabel $tab_extraParts "each part extra"
				-tabLabel $child3 "info"
				$tabs;

  	showWindow;
  	
}

bittnerRig_3;